Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
Memory/ The pair Game par SmartGenious
Auteur Message
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Bonjour à tous
je ne pouvais pas laisser passer ce jeu très bien réussi réalisé par un excellent batcheur nommé SmartGenius.

SmartGenius a réalisé un memory en utilisant une commande externe colous réalisé par Bolivianito, un collaborateur.
Tutoriel sur cette commande externe : http://foro.portalhacker.net/index.php?topic=96907.0



Son code source est disponible et j'espère que cela vous donnera de nouvelle idée.

Comment jouer ?

Sélectionne une cellule en cliquant dessus, et puis une seconde, si la paire est trouvé vous gagnez 10 points sinon vous perdez 5 points.

Code:

@Echo Off
@Title The Pair Game
@Mode Con Cols=30 Lines=12

Setlocal Enabledelayedexpansion
Color 0a
Colous Cursoroff

::Batch Game - The Pair Game
::Coded by SmartGenius
::Using COLOUS command from Bolivianito
::SmartGenius, Corp. 2010

:Load
Call :GenSymbols
Call :InitVars

:Init
Cls
Echo.
Echo. ÚÄÂÄÂÄÂÄÂÄÂÄ¿
Echo. ³°³°³°³°³°³°³   Score:%Points%
Echo. ÃÄÅÄÅÄÅÄÅÄÅÄ´
Echo. ³°³°³°³°³°³°³
Echo. ÃÄÅÄÅÄÅÄÅÄÅÄ´
Echo. ³°³°³°³°³°³°³
Echo. ÃÄÅÄÅÄÅÄÅÄÅÄ´
Echo. ³°³°³°³°³°³°³
Echo. ÀÄÁÄÁÄÁÄÁÄÁÄÙ
Echo.

:Coord
Set /a "R+=1"
For /f "tokens=*" %%a in ('Colous Mouse') do (Call :Check %%a)
Colous 14 8 24,3 "!Points!  "
If "%Pairs%"=="12" (
Colous 14 8 16,6 "You Win, press"
Colous 14 8 16,7 "  any key to"
Colous 14 8 16,8 " restart game"
Pause >nul
Goto :Load
)
Goto :Coord

:Check
For /l %%X in (3,2,13) do (
For /l %%Y in (3,2,9) do (
If Defined O_%~2_%~3 (Goto :Eof)
If "%~2 %~3"=="%%X %%Y" (
Colous 12 8 %2,%3 !V_%~2_%~3!
If Not Defined Sel_1 (
Set "Sel_1=!V_%~2_%~3!"
Set "Pos_1=%~2,%~3"
Goto :Eof
)
If Not Defined Sel_2 (
Set "Sel_2=!V_%~2_%~3!"
Set "Pos_2=%~2,%~3"
)
If Not "!Sel_1!"=="!Sel_2!" (
Set /a "Points-=5"
Ping -n 2 localhost >nul
Colous 10 8 !Pos_1! $176
Colous 10 8 !Pos_2! $176
Set "Sel_1="
Set "Sel_2="
Goto :Eof
) else (
Set /a "Points+=10"
Set /a "Pairs+=1"
Ping -n 2 localhost >nul
Colous 0 8 !Pos_1! $219
Colous 0 8 !Pos_2! $219
Set "Sel_1="
Set "Sel_2="
Call :Def !Pos_1! !Pos_2!
Goto :Eof
))))
Goto :Eof

:Def
If "%~1"=="" Goto :Eof
Set "O_%~1_%~2=Nul"
Shift&Shift
Goto :Def

:GenSymbols
Set "Symbols=$001,$002,$003,$004,$005,$006,$011,$012,$014,$015,$020,$021"
For %%S in (%Symbols%) do (
Set /a "S+=1"
Set "Symbol_!S!=%%S"
)
Goto :Eof

:InitVars
For /l %%X in (3,2,13) do (
For /l %%Y in (3,2,9) do (
Call :Generate "%%X" "%%Y"
Set "O_%%X_%%Y="
))
Set /a "Points=0","Pairs=0"
Goto :Eof

:Generate
Set /a "RX=(!Random! %% 12)+1"
If Defined Sym_%RX% (Goto :Generate)
If Not Defined S1_%RX% (
Set "V_%~1_%~2=!Symbol_%RX%!"
Set "S1_%RX%=Nul"
Goto :Eof
)
If Not Defined S2_%RX% (
Set "V_%~1_%~2=!Symbol_%RX%!"
Set "S2_%RX%=Nul"
Goto :Eof
)
Set "Sym_%RX%=Nul"
Goto :Generate


Télécharger l'archive : http://smart.code-makers.net/BatchGames/ThePairGameBySmartgenius.zip

COLOUS V5 : tutoriel syntaxe http://foro.portalhacker.net/index.php/topic,113484.0.html
Merci de respecter le travail de chacun si vous utilisez le travail d'autres.



Dernière édition par Laddy le Mar 27 Juil 2010 - 15:54; édité 1 fois

______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message Memory/ The pair Game par SmartGenious 
YOooo, trop cool la commande externe ^^
Moi qui était en manque d'inspiration ....

Bravo au codeur, le jeu est sympa !

@+




______________________________________________________


L'ignorance est un fléau qui engendre la haine et la mort
La connaissance est une arme qui surpasse toutes les autres
Partagez votre savoir, sinon il sera perdu à jamais
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
SmartGenius a réalisé d'autres jeux, il est balèse Very Happy
Il est espagnol il me semble comme Carlos Very Happy




______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
wouhaa cool ! Okay

Par contre quand je clique, ça ne fait rien... =(

ps: A quand un tuto pour utiliser cette commande ? Mr. Green




______________________________________________________
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Le lien vers un tutoriel est donné, un peu d'effort pour lire le sujet entièrement (ça fait deux fois....) et google translate peut être ton ami pour la traduction.
Moi qui ne parle pas un mot d'espagnol et mon italien est bien loin j'ai compris dans son ensemble, google translate a fait le reste..




______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Ajout du tutoriel pour colous v5
si quelqu'un parle couramment espagnol, n'hésitez pas poster votre traduction.




______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
jaja si, hablo poquito ^^

Voici donc un petit éclaircissement sur colous:

Pour savoir la position du click de la souris:
Code:

@echo off
:: \\ test colous
:up
cls

echo Cliquez la fenetre

for /f "tokens=1,2,3" %%W in ('colous mouse') do (
    set X=%%X
   set Y=%%Y
    )
echo.
echo Coordonnees du click: X=%X%  _  Y=%Y%
pause
goto :up


et en pratique on peux faire pleins de choses:
Code:

@echo off
:: \\ test colous

echo cliquez sur un mot

colous 11 0 1,5 "HOMME"
colous 13 0 1,8 "FEMME"

for /f "tokens=1,2,3" %%W in ('colous mouse') do (
    set X=%%X
   set Y=%%Y
    )

cls
if %Y%==5 echo Bonjour Monsieur
if %Y%==8 echo Bonjour Madame
pause>nul


Au besoin je peux ajouter d'autres tests suivant vos questions ...




______________________________________________________


L'ignorance est un fléau qui engendre la haine et la mort
La connaissance est une arme qui surpasse toutes les autres
Partagez votre savoir, sinon il sera perdu à jamais
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Laddy; j'avais été voir le tutoriel et traduit avec google translate (je ne parle pas español) avant que tu me le dise, mais j'avais rien compris quand même...

Merci stryk, c'est ce qu'il me fallait, je vais tester ça dès que je suis sur mon ordi Smile

++




______________________________________________________
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Hello
Deja MAGNIFIQUE commande externe =)
Mais aucun des codes de test, que tu as fait strik, ne marche chez moi...
Help ?
£`/@]




______________________________________________________


*Si l'erreur est humaine c'est parce que l'humanité en est une.*

£'/@] - Anciennement rekaca
MSN Skype
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Re,

Tu as téléchargé la commande COLOUS ??




______________________________________________________


L'ignorance est un fléau qui engendre la haine et la mort
La connaissance est une arme qui surpasse toutes les autres
Partagez votre savoir, sinon il sera perdu à jamais
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Biensur que oui Laughing
£`/@]




______________________________________________________


*Si l'erreur est humaine c'est parce que l'humanité en est une.*

£'/@] - Anciennement rekaca
MSN Skype
Répondre en citant
Message Memory/ The pair Game par SmartGenious 
Re,

Bizarre .... tu as essayé en mode admin' ?




______________________________________________________


L'ignorance est un fléau qui engendre la haine et la mort
La connaissance est une arme qui surpasse toutes les autres
Partagez votre savoir, sinon il sera perdu à jamais
Message Memory/ The pair Game par SmartGenious 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch