Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
[Batch] Pendu
Auteur Message
Répondre en citant
Message [Batch] Pendu 
Bonjour tout le monde !

Voilà, en aidant quelqu'un sur le SDZ, il s'est avéré qu'il voulait faire un pendu, j'ai décidé d'en faire un aussi. Il y a un mode 1 et 2 joueurs, pas besoin de rentrer chaque lettre séparément.
OS de développement : Windows 7 familiale 64 bits
OS compatibles : Normalement tous.

Code:
@echo off
setlocal enableDelayedExpansion
::################ Présentation ################
color 0B
echo.
echo.
echo       PPPPPPPP    EEEEEEEEE  NNNNNN      NNN  DDDDDD      UUU       UUU
echo       PPP   PPP   EEEEEEEEE  NNN NNN     NNN  DDD DDD     UUU       UUU
echo       PPP    PPP  EEE        NNN NNN     NNN  DDD  DDD    UUU       UUU
echo       PPP   PPP   EEE        NNN  NNN    NNN  DDD   DDD   UUU       UUU
echo       PPPPPPPP    EEEEEEE    NNN  NNN    NNN  DDD    DDD  UUU       UUU
echo       PPP         EEEEEEE    NNN   NNN   NNN  DDD    DDD  UUU       UUU
echo       PPP         EEE        NNN   NNN   NNN  DDD   DDD   UUU       UUU
echo       PPP         EEE        NNN    NNN  NNN  DDD  DDD     UUU     UUU
echo       PPP         EEEEEEEEE  NNN     NNN NNN  DDD DDD       UUUUUUUUU
echo       PPP         EEEEEEEEE  NNN      NNNNNN  DDDDDD         UUUUUUU
echo.
echo.
echo                                                                ÚÄÄÄÄÄÄÄÄÄÄÄÄ¿
echo                                                                ³ By Tufanik ³
echo                                                                ÀÄÄÄÄÄÄÄÄÄÄÄÄÙ
echo. &echo.
echo Appuyez sur une touche pour acc‚der au menu.
pause>nul
::################### Menu principal ######################
cls
color 0E
echo.
echo                                    ÉÍÍÍÍÍÍ»
echo                                    º Menu º
echo                                    ÈÍÍÍÍÍͼ
echo. &echo. &echo. &echo.
echo 1. Mode 1 joueur.
echo 2. Mode 2 joueur.
:choix
    set /p mode=^>^>
if not defined mode (
    echo Faites votre choix.
    goto :choix
)
if not %mode%==1 if not %mode%==2 (
    echo Entrez un choix valide.
    goto :choix
)
cls

::######### Mode 1 joueur ###################
if %mode%==1 (
    set i=0
    for /f %%I in ('type "dico.txt"') do set /a nbrLigne+=1
    set /a numMot=%random%%%!nbrLigne!
    for /f "tokens=1 delims=   " %%I in ('type "dico.txt"') do (
        set /a i+=1
        if !i!==!numMot! set mot=%%I
    )
)

::############### Mode 2 joueurs #############
if %mode%==2 (
    echo Entrez un mot … chercher :
    set /p mot=^>^>
)
cls

::########### Comptage des lettres ##########
set VrCompt=-1
:comptage
    set /a VrCompt+=1
    set test2=!mot:~%VrCompt%,1!
if not "%test2%"=="" goto comptage
echo Le mot contient %VrCompt% lettres.

::########## Mise en tableau ##########
::Le tableau va de 0 à "nombre de caractère - 1"
set /a VrCompt-=1
set /a LtrSuiv=1
for /L %%I in (0,1,%VrCompt%) do (
    set /a LtrSuiv+=1
    set tblLettre[%%I]=!mot:~%%I,%LtrSuiv%!
    set tblAffiche[%%I]=_
    set motTrouve=!motTrouve!!tblAffiche[%%I]!
)

::######### Recherche du mot #########
set nbrCoup=10
:recommencer
    echo %motTrouve%
    set lettrePresente=0
    echo Nombre de coups restant : %nbrCoup%
    :PasLettre
        echo Entrez une lettre :
        set motTrouve=
        set /p lettre=^>^>
    if not defined lettre goto :PasLettre
    for /L %%I in (0,1,%VrCompt%) do (
        if /i %lettre%==!tblLettre[%%I]! set tblAffiche[%%I]=%lettre%&set lettrePresente=1
        set motTrouve=!motTrouve!!tblAffiche[%%I]!
    )
    if %lettrePresente%==0 set /a nbrCoup-=1

::############## Perdu #############
    if %nbrCoup%==0 (
        cls
        color 0C
        echo Vous avez perdu, le mot ‚tait %mot%.
        echo. &echo Appuyez sur une touche pour quitter.
        echo. &echo. &echo. &echo.
        echo                                                    ,==========Y===
        echo                                                    ^|^|  /      ^|
        echo                                                    ^|^| /       ^|
        echo                                                    ^|^|/        O
        echo                                                    ^|^|        /^|\
        echo                                                    ^|^|        /^|
        echo                                                    ^|^|
        echo                                                   /^|^|
        echo                                                  //^|^|
        echo                                                 ============
        pause>nul
        exit
    )

::############### Gagné ##############
    if /i "%motTrouve%"=="%mot%" (
        cls
        color 0A
        echo Bravo, vous avez trouv‚ le mot %mot% !
        echo. &echo Appuyez sur une touche pour quitter.
        echo. &echo. &echo. &echo.
        echo                                                    thanks !
        echo                                                 \o
        echo                                                  ^|\
        echo                                                 / \
        pause>nul
        exit
    )
goto :recommencer


Je mets également le lien du fichier dico.txt qui contient un peu plus de 600 mots : http://www.box.com/s/gc8nzprm1o34peqim7qi
Vous pouvez ajouter des mots dans ce fichier, ils seront pris en compte.

Au niveau du jeu :
Les mots dans le fichier font partie des 600 mots les plus utilisés de la langue française.
Vous disposé de 10 coups pour trouver le mot.



Message Publicité 
PublicitéSupprimer les publicités ?


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch