Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
[Small Basic] Station d'accueil Réveil
Auteur Message
Répondre en citant
Message [Small Basic] Station d'accueil Réveil 
Hey ! Bonjour !

J'ai créé un petit écran d'accueil réveil avec fond perso.

Code:
'Initialisation fenêtre
GraphicsWindow.Height=Desktop.Height
GraphicsWindow.Width=Desktop.Width
GraphicsWindow.Title="Écran d'accueil par Jio15"
GraphicsWindow.Top=-20
GraphicsWindow.Left=-5
GraphicsWindow.CanResize="false"

alarmEnabled="false"

Debut:
GraphicsWindow.Hide()
GraphicsWindow.Clear()

'Placement de l'image de fond
imagefond=Program.Directory+"\fond.jpg"
GraphicsWindow.DrawResizedImage(imagefond, 0, 0, GraphicsWindow.Width, GraphicsWindow.Height)

'Textes
'----Bouton
GraphicsWindow.BrushColor="black"
GraphicsWindow.FontBold="false"
GraphicsWindow.FontSize=20
boutonReveil = Controls.AddButton("Définir un réveil",0,GraphicsWindow.Height-35)
'----Heure
GraphicsWindow.BrushColor="white"
GraphicsWindow.FontBold="true"
GraphicsWindow.FontSize=200
heure=Shapes.AddText("00:00")
'---Date
GraphicsWindow.FontBold="false"
GraphicsWindow.FontSize=70
date=Shapes.AddText("xxxxxxx 00/00/00")
'---Alarme
GraphicsWindow.BrushColor="white"
GraphicsWindow.FontBold="true"
GraphicsWindow.FontSize=20
If alarmEnabled="true" then
  GraphicsWindow.DrawText(160,GraphicsWindow.Height-30,"Réveil défini à "+heureAlarm+":"+minuteAlarm)
Endif

'Positionnement des textes
Shapes.Move(heure,GraphicsWindow.Width/2-300,GraphicsWindow.Height/2-250)
Shapes.Move(date,GraphicsWindow.Width/2-300,GraphicsWindow.Height/2-20)

Controls.ButtonClicked = alarm 'Si on clique sur le bouton, aller à "Sub alarm"
GraphicsWindow.KeyDown = key 'Si on appuie sur une touche, aller à "Sub key"

GraphicsWindow.Show()

Boucle: 'Boucle d'actualisation pour la date et l'heure

If alarmNew="true" then 'Si l'alarme vient d'être définie,
  alarmNew="false"
  Goto debut 'remets l'affichage comme avant.
endif

'Mise à jour de la date et de l'heure :
Shapes.SetText(heure,text.GetSubText(Clock.Time,1,5))
Shapes.SetText(date,Clock.WeekDay+" "+Clock.Date)

'Si l'heure de l'alarme est atteinte, fais sonner :
If alarmEnabled="true" and Clock.Hour=heureAlarm and Clock.Minute=minuteAlarm Then
  GraphicsWindow.Clear()
  GraphicsWindow.DrawResizedImage(imagefond, 0, 0, GraphicsWindow.Width, GraphicsWindow.Height)
  GraphicsWindow.BrushColor="white"
  GraphicsWindow.FontBold="true"
  GraphicsWindow.FontSize=150
  GraphicsWindow.DrawText(GraphicsWindow.Width/2-500,GraphicsWindow.Height/2-120,"C'est l'heure !")
  While 1=1
    Sound.PlayMusic("O5 C4 C C D E R5 D R5 C E D D C")
    Program.Delay(1000)
  EndWhile
Endif

'Attendre une seconde avant de remettre à jour (éviter le surplus de calcul) :
Program.Delay(1000)
Goto boucle



Sub alarm
  If Controls.LastClickedButton = boutonReveil Then
    'Définir un réveil
    GraphicsWindow.Clear()
   
    GraphicsWindow.DrawResizedImage(imagefond, 0, 0, GraphicsWindow.Width, GraphicsWindow.Height)
   
    GraphicsWindow.BrushColor="white"
    GraphicsWindow.FontBold="true"
    GraphicsWindow.FontSize=100
    GraphicsWindow.DrawText(GraphicsWindow.Width/2-420,GraphicsWindow.Height/2-200,"Heure du réveil :")
    GraphicsWindow.FontSize=80
    GraphicsWindow.DrawText(GraphicsWindow.Width/2-40,GraphicsWindow.Height/2-80,":")
   
    GraphicsWindow.BrushColor="black"
    GraphicsWindow.FontBold="true"
    GraphicsWindow.FontSize=80
    textboxH = Controls.AddTextBox(GraphicsWindow.Width/2-150,GraphicsWindow.Height/2-70)
    Controls.SetSize(textboxH,115,100)
    textboxM = Controls.AddTextBox(GraphicsWindow.Width/2-15,GraphicsWindow.Height/2-70)
    Controls.SetSize(textboxM,115,100)
   
    GraphicsWindow.FontBold="false"
    GraphicsWindow.FontSize=30
    valider = Controls.AddButton("Valider",GraphicsWindow.Width/2-150,GraphicsWindow.Height/2+30)
    Controls.SetSize(valider,250,60)
  EndIf
  If Controls.LastClickedButton = valider Then
    'Valider la définition du réveil
    heureAlarm=Controls.GetTextBoxText(textboxH)
    minuteAlarm=Controls.GetTextBoxText(textboxM)
    alarmEnabled="true"
    alarmNew="true"
  EndIf
EndSub

Sub Key
  If GraphicsWindow.LastKey="Escape" Then
    Program.End()
  EndIf
EndSub


À vous de créer fond.jpg.
Personnellement j'ai une préférence pour celui-ci.

Ce qui donne, en un seul exe : http://www.sendspace.com/file/9okyp7

Merci de vos commentaires.



Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message [Small Basic] Station d'accueil Réveil 
Ce fond.jpg peut ne pas être mal non plus (j'ai personnellement escamoté la partie droite avec le copyright, libre à vous de faire pareil ou non)



Message [Small Basic] Station d'accueil Réveil 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch