Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 3
Aller à la page: 1, 2, 3  >
Labyrinthe
Avez-vous trouvé la sortie de la map 'map01' ?

Oui 77% 77% ( 7 )
Non 0% 0% ( 0 )
Ca m'saoûle ! 22% 22% ( 2 )

Total des votes : 9
Auteur Message
Répondre en citant
Message Labyrinthe 
Salut à tous !

EDIT : le projet évolu, regardez les posts suivants pour obtenir la dernière version !

Je vous propose ici un labyrinthe que j'ai créé qui a la particularité de permettre la création de ses propres maps (explications plus loin).



Les fichiers sont récupérables ici.

Pour commencer, voici le script qui lit les maps :

Code:
rem  CONFIG
set map=
set title=laby v0.1b
title %title% %map%
mode con cols=40 lines=30
@echo off
cls

rem  CHOICE
echo.
echo.
echo.
echo                  LABY
echo                    v0.1b
set tmp=0
echo.
echo.
echo.
echo.
echo   ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
echo   º Choose a map
echo   º
for /f %%i in ('DIR .\maps\*.laby /b') do echo   º     - %%~ni
echo   º
echo   º Type map name:
set /p map=
if not exist .\maps\%map%.laby goto QUIT

rem  INIT
set map=.\maps\%map%.laby
set tmp=%RANDOM%%RANDOM%.tmp
set go=LOAD
set win=0
set rep=0

:START
find "NAME" %map% > %tmp%
echo   º
echo   º
echo   º
echo   º       *** INFORMATIONS ***
echo   º
for /f "tokens=2 delims=;" %%i in (%tmp%) do echo   º Name: %%i
for /f "tokens=3 delims=;" %%i in (%tmp%) do echo   º Decription: %%i
find "AUTHOR" %map% > %tmp%
echo   º
for /f "tokens=2-3 delims=;" %%i in (%tmp%) do echo   º Author: %%i %%j
find "DATE" %map% > %tmp%
for /f "tokens=2-3 delims=;" %%i in (%tmp%) do echo   º Date: %%i %%j

:PAUSE
echo   º
echo   º Please hit a key to continue...
pause > NUL
goto %go%

:LOAD
color 08
cls
echo   º
echo   º Loading map...
echo   º
find "SIZE" %map% > %tmp%
for /f "tokens=2 delims=;" %%i in (%tmp%) do set size_h=%%i
for /f "tokens=3 delims=;" %%i in (%tmp%) do set size_v=%%i
echo   º --- Size: %size_h%x%size_v%
find "START" %map% > %tmp%
for /f "tokens=2 delims=;" %%i in (%tmp%) do set pos_h=%%i
set /a pos_h = %pos_h% + 1
for /f "tokens=3 delims=;" %%i in (%tmp%) do set pos_v=%%i
echo   º --- Start position: (%pos_h%;%pos_v%)
find "EXIT" %map% > %tmp%
for /f "tokens=2 delims=;" %%i in (%tmp%) do set exit_h=%%i
set /a exit_h = %exit_h% + 1
for /f "tokens=3 delims=;" %%i in (%tmp%) do set exit_v=%%i
echo   º --- Exit position: (%exit_h%;%exit_v%)
find "MAP%pos_v%" %map% > %tmp%
for /f "tokens=%pos_h% delims=;" %%i in (%tmp%) do set pos=%%i
echo   º --- Start number: %pos%
find "MAP%exit_v%" %map% > %tmp%
for /f "tokens=%exit_h% delims=;" %%i in (%tmp%) do set exit=%%i
echo   º --- Exit number: %exit%
echo   º
echo   º Starting the game...
echo   º
mode con cols=40 lines=25
color 0F
title %title% %map%
goto GAME

:GAME
cls
echo  %title% %map%
echo.
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
goto %pos%

:00
rem  useless
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=0
set d=0
set l=0
set r=0
goto ACTION

:01
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo.
echo              ^<     ()     ^>
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=0
set d=0
set l=1
set r=1
goto ACTION

:02
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  ()  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=1
set d=1
set l=0
set r=0
goto ACTION

:03
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ
echo              ÛÛÛÛ  ()     ^>
echo              ÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=1
set d=0
set l=0
set r=1
goto ACTION

:04
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo                        ÛÛÛÛ
echo              ^<     ()  ÛÛÛÛ
echo                        ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=0
set d=1
set l=1
set r=0
goto ACTION

:05
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛ
echo              ÛÛÛÛ  ()     ^>
echo              ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=0
set d=1
set l=0
set r=1
goto ACTION

:06
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo                        ÛÛÛÛ
echo              ^<     ()  ÛÛÛÛ
echo                        ÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=1
set d=0
set l=1
set r=0
goto ACTION

:07
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛ
echo              ÛÛÛÛ  ()     ^>
echo              ÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=0
set d=0
set l=0
set r=1
goto ACTION

:08
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo                        ÛÛÛÛ
echo              ^<     ()  ÛÛÛÛ
echo                        ÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=0
set d=0
set l=1
set r=0
goto ACTION

:09
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  ()  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=1
set d=0
set l=0
set r=0
goto ACTION

:10
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  ()  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=0
set d=1
set l=0
set r=0
goto ACTION

:11
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ
echo              ÛÛÛÛ  ()     ^>
echo              ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=1
set d=1
set l=0
set r=1
goto ACTION

:12
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo                        ÛÛÛÛ
echo              ^<     ()  ÛÛÛÛ
echo                        ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=1
set d=1
set l=1
set r=0
goto ACTION

:13
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo.
echo              ^<     ()     ^>
echo.
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=0
set d=1
set l=1
set r=1
goto ACTION

:14
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo.
echo              ^<     ()     ^>
echo.
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
echo              ÛÛÛÛÛÛÛÛÛÛÛÛÛÛ
set u=1
set d=0
set l=1
set r=1
goto ACTION

:15
echo.
echo              ÛÛÛÛ  /\  ÛÛÛÛ
echo              ÛÛÛÛ      ÛÛÛÛ
echo.
echo              ^<     ()     ^>
echo.
echo              ÛÛÛÛ      ÛÛÛÛ
echo              ÛÛÛÛ  \/  ÛÛÛÛ
set u=1
set d=1
set l=1
set r=1
goto ACTION

:ACTION
set /a pos_x = %pos_h% - 1
set pos_y=%pos_v%
echo  (%pos_x%;%pos_y%)
echo.
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
if %win%==1 goto END

echo  Where do you want to go?
echo.
if %u%==1 (echo      [Z] Up) else echo.
if %l%==1 (echo      [Q] Left) else echo.
if %d%==1 (echo      [S] Down) else echo.
if %r%==1 (echo      [D] Right) else echo.
echo.
set /p rep= [Z;Q;S;D]:
if %u%==1 (
   if %rep%==Z set /a pos_v = %pos_v% - 1
   if %rep%==z set /a pos_v = %pos_v% - 1
)
if %l%==1 (
   if %rep%==Q set /a pos_h = %pos_h% - 1
   if %rep%==q set /a pos_h = %pos_h% - 1
)
if %d%==1 (
   if %rep%==S set /a pos_v = %pos_v% + 1
   if %rep%==s set /a pos_v = %pos_v% + 1
)
if %r%==1 (
   if %rep%==D set /a pos_h = %pos_h% + 1
   if %rep%==d set /a pos_h = %pos_h% + 1
)
if %rep%==quit goto QUIT
if %rep%==exit goto QUIT
if %pos_h%==%exit_h% if %pos_v%==%exit_v% set win=1
find "MAP%pos_v%" %map% > %tmp%
for /f "tokens=%pos_h% delims=;" %%i in (%tmp%) do set pos=%%i
goto GAME

:END
title %title% YOU WIN!
color 0A
echo.
echo   º YOU WIN!
set go=QUIT
goto PAUSE

:QUIT
title %title% BYE!
color 08
cls
echo.
echo   º BYE!
if %tmp%==0 exit
del %tmp%
exit


Maintenant les maps en question :

Map de test :
Code:
#inf
SIZE;3;3
START;3;3
EXIT;1;1
NAME;TEST;test map
AUTHOR;bigeyes;
DATE;16/07/2012;16:00

#map
MAP1;01;13;04
MAP2;10;02;09
MAP3;03;14;08


Première map :
Code:
#inf
SIZE;9;9
START;3;9
EXIT;9;3
NAME;MAP01;1st map
AUTHOR;bigeyes;
DATE;17/07/2012;15:00

#map
MAP1;05;04;05;13;01;01;01;04;10
MAP2;02;02;02;02;05;01;04;11;12
MAP3;09;03;06;02;02;05;12;09;03
MAP4;07;01;01;14;15;06;03;01;08
MAP5;05;13;13;01;14;04;05;01;04
MAP6;09;02;02;10;05;12;03;04;02
MAP7;05;06;02;03;12;02;05;06;02
MAP8;02;05;12;05;14;06;03;04;02
MAP9;03;06;09;03;01;01;01;14;06



Maintenant allons-y pour les explications !

Comme vous avez pu le constater, les maps sont séparées du script, ce qui permet d'en créer soi-même pour ensuite les lire.
Celles-ci sont composées de différents champs :

Code:
#une partie contient les informations sur la map
SIZE;X;X #correspond à la taille du labyrinthe sous la forme largeur;hauteur
START;X;X #correspond à la position de départ, toujours sous la forme largeur;hauteur
EXIT;X;X #correspond à la position de la sortie
#les trois infos ci-dessus sont obligatoires pour le bon fonctionnement du script !
NAME;TRUC;machin #NOM_DE_LA_MAP;description
AUTHOR;truc;machin #auteur;infos
DATE;XX/XX/XXXX;XX:XX #date;heure
#ces trois champs sont facultatifs

#l'autre partie concerne la map en elle-même
#chaque ligne se présente sous la forme MAPX;XX;XX;XX;XX;XX, MAPX où X est le numéro de ligne, et XX le type de chemin.
#si c'est pas très clair regardez les fichiers d'exemple, tout devrait devenir limpide
MAP1;01;13;04
MAP2;10;02;09
MAP3;03;14;08



Les chiffres correspondent à différents type de chemins dont voici le schéma :

Code:
  00        01        02        03
######    ######    ##  ##    ##  ##
######              ##  ##    ##
######    ######    ##  ##    ######

  04        05        06        07
######    ######    ##  ##    ######
    ##    ##            ##    ##
##  ##    ##  ##    ######    ######

  08        09        10        11
######    ##  ##    ######    ##  ##
    ##    ##  ##    ##  ##    ##
######    ######    ##  ##    ##  ##

  12        13        14        15
##  ##    ######    ##  ##    ##  ##
    ##
##  ##    ##  ##    ######    ##  ##


Enfin toutes les maps doivent être placées dans un dossier 'maps' situé au niveau du script et porter l'extension '.laby'.

Voili voilou, je vais peut-être y incorporer des p'tits trucs en plus (du style pièges, énigmes et autres), et si vous avez des questions ou des avis faîtes-moi signe ;-)



Dernière édition par bigeyes le Dim 2 Déc 2012 - 15:46; édité 1 fois
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message Labyrinthe 
Bonjour
intéressant comme jeu, reste à voir en pratique

Carlos a développé une commande qui permet d utiliser les fleches directionnelles du clavier ça peut peut etre t intéressé
http://batch.xoo.it/t2238-BG-exe-Utility-for-Batch-Games.htm

Oh et pis moi j ai mis à disposition la création d un menu dynamique en batch qui numérote les fichiers contenu dans un dossier

{{{Vous devez répondre à ce sujet pour voir la partie cachée}}}





______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Répondre en citant
Message Labyrinthe 
Laddy a écrit:
Bonjour
intéressant comme jeu, reste à voir en pratique

Carlos a développé une commande qui permet d utiliser les fleches directionnelles du clavier ça peut peut etre t intéressé
http://batch.xoo.it/t2238-BG-exe-Utility-for-Batch-Games.htm

Oh et pis moi j ai mis à disposition la création d un menu dynamique en batch qui numérote les fichiers contenu dans un dossier

{{{Vous devez répondre à ce sujet pour voir la partie cachée}}}


ça a l'air sympa bg, je vais voir ce que je peux en tirer, merci pour les infos !



Répondre en citant
Message Labyrinthe 
Salut a tous,


Merci bigeyes pour ce super jeux Wink, je vais essayer d'ajouter
des options tel qu'une sauvegarde, customize color/touches etc...

Super code en tout cas !



Cordialement, Pierrot



Répondre en citant
Message Labyrinthe 
Pas de quoi ^^

Poste ton code quand tu auras rajouté tes idées que je teste ça !!

Bon courage ;-)



Répondre en citant
Message Labyrinthe 
Salut a tous,

J'ai reussi t'a map au bout de 48 pas (j'ai rajoute un petit compteur)

Voici une map assez facile que j'ai faite (Vous pouvez la reussir en 6pas) :

Code:

    #inf
    SIZE;4;5
    START;4;5
    EXIT;2;3
    NAME;Test;Ma premiere map !
    AUTHOR;Pierre JOUSSAIN;
    DATE;30/11/2012;18:24
     
    #map
    MAP1;05;13;13;04
    MAP2;02;03;12;02
    MAP3;11;08;11;12
    MAP4;11;01;15;12
    MAP5;09;07;14;06


Voila, et pour les version plus récentes de windows (7 par ex)
il faudrait utiliser la commande choice, sa serait pas mal !
Je vais voir sa...



Cordialement, Pierrot



Répondre en citant
Message Labyrinthe 
Bonjour
dans un batch on essaie de le rendre le plus compatible avec des OS, donc la commande choice n est pas un choix judicieux non dispo sous xp.




______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Répondre en citant
Message Labyrinthe 
Effectivement, mais en vérifiant si la commande existe, cela
pourrais etre intéressant non ?

Code:

set procom=acp
Choice /N /T:Y,1 >Nul 2>&1
If "%Errorlevel%"=="9009" set procom=pro
if not exist "%windir%\System32\choice.exe" set procom=pro

if pro equ %procom% goto chpro
commande "choice"
+résultats
goto chorse

:chpro
commande set /p
+résultats

:chorse
Suite du programme...


Je sais pas....



Cordialement, Pierrot



Répondre en citant
Message Labyrinthe 
Je ne vois pas ce qu il peut etre intressant dans la commande choice , pourrais tu me dire quel intéret tu y vois ?
et pourquoi lutiliser




______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Répondre en citant
Message Labyrinthe 
Cela aurais permis de ne pas valider "entrée" a chaque fois
que l'on veuille avancer...



Répondre en citant
Message Labyrinthe 
ok je vois dans le cas choice en hex pour le reconstituer sous xp peut etre une idée

j attends de voir ton adaptation Okay




______________________________________________________
Faites paraitre votre batch sur BatchClipboard
Visiter le site web du posteur
Répondre en citant
Message Labyrinthe 
Salut !

Sympa ta map Pierrot ;-) J'ai pas encore réussi en 6 pas ^^ Tu pourrais poster le code pour le compteur ? J'y avais pas pensé mais c'est une très bonne idée !!!

Et pour CHOICE ça pourrait être bien, je ne savais pas que ça éviterait de valider à chaque fois, mais la vérification de l'OS me semble effectivement importante.



Répondre en citant
Message Labyrinthe 
Hello Mr. Green

Je passais par là et j'ai regardé d'un peu plus près..

Et je vous demande donc -> pourquoi ne pas utiliser batbox.exe?


++ Okay




______________________________________________________
│Øδ@π.
Visiter le site web du posteur Skype
Répondre en citant
Message Labyrinthe 
Comme mon system d'exploitation est win 64bits, je ne peut pas convertir choice.exe en hexa, mais je vais essayer d'adapter la commande, je vous posterais le code se soir(si j'ai le droit au PC Wink )

Pour le compteur c'est tout simple (je posterais le code egalement se soir)
Quand tu initialise tu met la var a 0 et +1 a chaque deplacement Wink

Lady a deja parler de la commande batbox (plus haut), je n sais pas ou sa en ai...
Autant pour moi, c'était la commande bg.exe, je ne suis pas adepte de ces commandes, mais il y a un début a tout Smile


Cordialement, Pierrot



Répondre en citant
Message Errorlevel pour Laby 
Voici la commande errorlevel (fonctionnelle chez moi), je ne suis pas sur que chez vous cela fonctionne
parfaitement donc faites une copie avant toute chose et si vous trouvez un problème, dites-le moi :

PS : J'ai egelament rajouter le conteur de pas (ou deplacement)

Code:

::A METTRE TOUT AU DEBUT DU CODE
set procom=acp
Choice /N /T:Y,1 >Nul 2>&1
If "%Errorlevel%"=="9009" set procom=pro
if not exist "%windir%\System32\choice.exe" set procom=pro

::A METTRE LORS DU "LOAD" DU JEU
set pas=0

::A METTRE LORS DE LA DEMANDE "DEPLACEMENT"
:ACTION
set /a pos_x = %pos_h% - 1
set pos_y=%pos_v%
echo Pas : %pas% (%pos_x%;%pos_y%)
echo.
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
if %win%==1 goto END

echo  Ou souhaitez-vous aller ?
echo.
if %u%==1 (echo      [Z] Haut) else echo.
if %l%==1 (echo      [Q] Gauche) else echo.
if %d%==1 (echo      [S] Bas) else echo.
if %r%==1 (echo      [D] Droite) else echo.
echo.
if pro equ %procom% goto chpro

:Move
REM CHOICE /C ZQSD /N >nul
CHOICE /C:ZQSD /N
If "%errorlevel%"=="1" if %u%==1 set /a pos_v = %pos_v% - 1
If "%errorlevel%"=="2" if %l%==1 set /a pos_h = %pos_h% - 1
If "%errorlevel%"=="3" if %d%==1 set /a pos_v = %pos_v% + 1
If "%errorlevel%"=="4" if %r%==1 set /a pos_h = %pos_h% + 1
goto chorse

:chpro
set /p rep= [Z;Q;S;D]:
if %u%==1 (
   if %rep%==Z set /a pos_v = %pos_v% - 1
   if %rep%==z set /a pos_v = %pos_v% - 1
)
if %l%==1 (
   if %rep%==Q set /a pos_h = %pos_h% - 1
   if %rep%==q set /a pos_h = %pos_h% - 1
)
if %d%==1 (
   if %rep%==S set /a pos_v = %pos_v% + 1
   if %rep%==s set /a pos_v = %pos_v% + 1
)
if %r%==1 (
   if %rep%==D set /a pos_h = %pos_h% + 1
   if %rep%==d set /a pos_h = %pos_h% + 1
)
if %rep%==quit goto QUIT
if %rep%==exit goto QUIT
:chorse
if %pos_h%==%exit_h% if %pos_v%==%exit_v% set win=1
find "MAP%pos_v%" %map% > %tmp%
for /f "tokens=%pos_h% delims=;" %%i in (%tmp%) do set pos=%%i
set /a pas=%pas%+1
goto GAME


Si je ne poste pas le reste du code, c'est parce que je suis en train de le modifier, je posterais les
modifications au fur et a mesure du développement.



Cordialement, Pierrot



Message Labyrinthe 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 3
Aller à la page: 1, 2, 3  >
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch