Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
[RÉSOLU] Help me please
Auteur Message
Répondre en citant
Message [RÉSOLU] Help me please 
Hello j'aurai besoin d'extraire une valeur de fichier ini dans un batch es que quelqu'un a une idée?
Voici le fichier ini :


[CONNEXION_DEFAUT]
NOM_SERVEUR_SQL= "VALEUR A RECUPERER"
INSTANCE_SQL=
COMPTE_SQL=
MOT_DE_PASSE_SQL=
[MAJEURE]
VERSION=4.1

Merci pour votre aide et vos idees seront bienvenu



Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message [RÉSOLU] Help me please 
Slt Gilles

Tu es bien tombé!
Je t'esplique ça demain soir car là je poste à 11h00 du soir^^
Ps ton batch servira à quoi après?




______________________________________________________
Visiter le site web du posteur
Répondre en citant
Message [RÉSOLU] Help me please 
Salut !

une solution pour faire ce que tu veux est: (la valeur a récupérer doit être unique dans le fichier) :

Code:
for /F "tokens=1,2 delims==" %%a in ('type TON_FICHIER ^| find "NOM_SERVEUR_SQL="') do set %%a=%%b
echo %nom_serveur_sql%


on pourrait s'amuser a charger toutes les valeur du fichier ini en remplaçant "NOM_SERVEUR_SQL=" seulement par "="

a plus !

Edit: j'ai déplacé le sujet dans la section appropriée. Merci d'éviter les doublons à l'avenir...




______________________________________________________
--
> Que pensez vous de l'ajout du repertoire point dans $PATH ?
Ma version de troll 18.0.32 beta 3 vient de me faire un core dump.
-+- SE in Guide du Linuxien Pervers : Bien développer son troll -+-

[Dos9]
Visiter le site web du posteur Skype
Répondre en citant
Message Gros merci 
salut je viens d'essayer sa marche nickel.
Je te remercie, désolé pour le doublon Smile



Répondre en citant
Message [RÉSOLU] Help me please 
Salut Wink
Si vous me permettez d'ajouter une autre solution mais en Vbscript juste pour varier un peu les solutions, on sait jamais peut-être un autre membre veut une solution en Vbscript Laughing
Code:
Option Explicit
Function ReadIni( myFilePath, mySection, myKey )
    ' This function returns a value read from an INI file
    '
    ' Arguments:
    ' myFilePath  [string]  the (path and) file name of the INI file
    ' mySection   [string]  the section in the INI file to be searched
    ' myKey       [string]  the key whose value is to be returned
    '
    ' Returns:
    ' the [string] value for the specified key in the specified section
    '
    ' CAVEAT:     Will return a space if key exists but value is blank
    '
    ' Written by Keith Lacelle
    ' Modified by Denis St-Pierre and Rob van der Woude

    Const ForReading   = 1
    Const ForWriting   = 2
    Const ForAppending = 8

    Dim intEqualPos
    Dim objFSO, objIniFile
    Dim strFilePath, strKey, strLeftString, strLine, strSection

    Set objFSO = CreateObject( "Scripting.FileSystemObject" )

    ReadIni     = ""
    strFilePath = Trim( myFilePath )
    strSection  = Trim( mySection )
    strKey      = Trim( myKey )

    If objFSO.FileExists( strFilePath ) Then
        Set objIniFile = objFSO.OpenTextFile( strFilePath, ForReading, False )
        Do While objIniFile.AtEndOfStream = False
            strLine = Trim( objIniFile.ReadLine )

            ' Check if section is found in the current line
            If LCase( strLine ) = "[" & LCase( strSection ) & "]" Then
                strLine = Trim( objIniFile.ReadLine )

                ' Parse lines until the next section is reached
                Do While Left( strLine, 1 ) <> "["
                    ' Find position of equal sign in the line
                    intEqualPos = InStr( 1, strLine, "=", 1 )
                    If intEqualPos > 0 Then
                        strLeftString = Trim( Left( strLine, intEqualPos - 1 ) )
                        ' Check if item is found in the current line
                        If LCase( strLeftString ) = LCase( strKey ) Then
                            ReadIni = Trim( Mid( strLine, intEqualPos + 1 ) )
                            ' In case the item exists but value is blank
                            If ReadIni = "" Then
                                ReadIni = " "
                            End If
                            ' Abort loop when item is found
                            Exit Do
                        End If
                    End If

                    ' Abort if the end of the INI file is reached
                    If objIniFile.AtEndOfStream Then Exit Do

                    ' Continue with next line
                    strLine = Trim( objIniFile.ReadLine )
                Loop
            Exit Do
            End If
        Loop
        objIniFile.Close
    Else
        WScript.Echo strFilePath & " doesn't exists. Exiting..."
        Wscript.Quit 1
    End If
End Function
Dim MaValeur : MaValeur = ReadIni("c:\File.ini","CONNEXION_DEFAUT","NOM_SERVEUR_SQL")
MsgBox "La valeur du NOM_SERVEUR_SQL est: " & MaValeur,64,"NOM_SERVEUR_SQL"





______________________________________________________
Mes Contributions en Téléchargement
Répondre en citant
Message [RÉSOLU] Help me please 
Sujet résolu Wink




______________________________________________________


L'ignorance est un fléau qui engendre la haine et la mort
La connaissance est une arme qui surpasse toutes les autres
Partagez votre savoir, sinon il sera perdu à jamais
Message [RÉSOLU] Help me please 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch