Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
Probleme FTP
Auteur Message
Répondre en citant
Message Probleme FTP 
Bonjour,

je n'ai jamais développer en autoit et je voulais vous demander :

Je voudrais faire un logiciel qui quand il s'ouvre affiche ceci :

Numéro de la version [Télécharger]

Télécharger serais un boutton et le numéro de la version un simple texte, je ne sais comment faire,
je galere aussi sur le protocole de téléchargement ftp que j'ai trouver :

Code:

#include <FTPEx.au3>
#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <ProgressConstants.au3>

Global $g_sRemoteFile = "version/GoFox1.2.9.rar"
Global $g_sLocalFile = "/t/"
FileDelete($g_sLocalFile)

Local $sServer = '185.28.20.41'
Local $sUsername = ''
Local $sPass = ''

Local $hInternetSession = _FTP_Open('Téléchargement')
; passive allows most protected FTPs to answer
Local $hFTPSession = _FTP_Connect($hInternetSession, $sServer, $sUsername, $sPass, 1)

Example()

_FTP_Close($hInternetSession)

Func Example()
   Local $sFunctionToCall = "_UpdateProgress"
   ProgressOn("Téléchargement en cours.", $g_sRemoteFile)
   _FTP_ProgressDownload($hFTPSession, $g_sLocalFile, $g_sRemoteFile, $sFunctionToCall)
   ProgressOff()
EndFunc   ;==>Example

Func _UpdateProgress($iPercent)
   ProgressSet($iPercent, Int($iPercent) & "%")
   If _IsPressed("77") Then Return 0 ; Abort on F8
   Return 1 ; 1 to continue Download
EndFunc   ;==>_UpdateProgress



Merci de votre aide



Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message Probleme FTP 
Pourquoi passer par du FTP ?

Fais le avec INETGET

Okay

Ou en HTTP avec VBS

http://batch.xoo.it/t4371-VBS-BAT-Faire-un-syst-me-d-update-automatique.htm

Okay




______________________________________________________
AffPng.exe , StringBetween.exe , Hex2Png.exe
Répondre en citant
Message Probleme FTP 
Salut,

si sa t'intéresse voici un petit exemple commenté qui permet de faire un téléchargement en FTP:

Code:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <FTPEx.au3>
#include <Misc.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Test FTP", 615, 191, 419, 297)
$Progress_bar1 = GUICtrlCreateProgress(224, 88, 361, 33)
$Label_ftp_fichier = GUICtrlCreateLabel("Fichier ftp à télécharger:", 8, 16, 118, 17)
$Input_ftp_fichier = GUICtrlCreateInput("ftp://mirrors.ircam.fr/pub/OpenBSD/doc/history/obsd-faq-fr47.pdf", 136, 16, 449, 21)
$Label_dossier_dst = GUICtrlCreateLabel("Dossier de destination:", 8, 48, 111, 17)
$Input_dossier_dst = GUICtrlCreateInput(@ScriptDir, 136, 48, 449, 21)
$Button_telecharger = GUICtrlCreateButton("Télécharger", 64, 88, 153, 33)
$Button_ouvrir_dossier = GUICtrlCreateButton("Ouvrir le dossier", 64, 136, 153, 33)
$Button_exec_fichier = GUICtrlCreateButton("Exécuter le fichier", 224, 136, 153, 33)
$label_info= GUICtrlCreateLabel("en attente de téléchargement", 400, 136, 190, 30)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

global $nom_du_fichier ;creation de la variable générale "$nom_du_fichier" pour pouvoir l'utiliser avec le bouton "Exécuter le fichier"

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         Exit
      case $Button_telecharger
         _telecharger()
      case $Button_ouvrir_dossier
         ShellExecute(GUICtrlRead($Input_dossier_dst))
      case $Button_exec_fichier
         if $nom_du_fichier = "" then
            MsgBox(16,"erreur","veuillez télécharger le fichier pour pouvoir l'ouvrir")
         Else
            if FileExists(GUICtrlRead($Input_dossier_dst)&"\"&$nom_du_fichier) = 0 then
               MsgBox(16,"erreur","fichier inexistant")
            Else
               ShellExecute(GUICtrlRead($Input_dossier_dst)&"\"&$nom_du_fichier)
            EndIf
         EndIf
   EndSwitch
WEnd

func _telecharger()
   ;initialisation des variables
   $split_ftp_fichier=StringSplit(GUICtrlRead($Input_ftp_fichier),"/");récupére dans un tableau toutes les chaines séparées par "/"
   $serveur=$split_ftp_fichier[3];le serveur correspond à la troisieme chaine du tableau "$split_ftp_fichier"
   $nom_du_fichier=$split_ftp_fichier[$split_ftp_fichier[0]];définition du fichier qui correspond à la dernière chaine du tableau "$split_ftp_fichier"
   $destination_complete=GUICtrlRead($Input_dossier_dst)&"\"&$nom_du_fichier;définition du chemin complet du fichier de destination (dossier + nom du fichier)
   $chemin_ftp_source=StringTrimLeft(GUICtrlRead($Input_ftp_fichier),6+StringLen($serveur));définition du chemin ftp qui correspond à "$Input_ftp_fichier" moins la longeur de "ftp://mirrors.ircam.fr" en partant de la gauche
   $sUsername=""
   $sPass=""
   $fonction_progression = "_mise_a_jour_progression" ;nom de la fonction de mise à jour de progression
   if FileExists($destination_complete) then return GUICtrlSetData($label_info,"erreur, le fichier existe déjà");si le fichier existe on quite la fonction en cours en affichant une erreur
   if FileExists(GUICtrlRead($Input_dossier_dst))=0 then return GUICtrlSetData($label_info,"erreur, la destination n'existe pas")

   ;connexion au serveur
   $session_ftp = _FTP_Open('FTP test');creation de l'environnement FTP
   if @error then return GUICtrlSetData($label_info,"erreur _FTP_Open:"&@error)
   $connexion_ftp = _FTP_Connect($session_ftp, $serveur, $sUsername, $sPass, 1);connexion au serveur
   if @error then return GUICtrlSetData($label_info,"erreur _FTP_Connect:"&@error)

   ; téléchargement
    _FTP_ProgressDownload($connexion_ftp, $destination_complete, $chemin_ftp_source, $fonction_progression);cette commande exécute le téléchargement tout en appelant périodiquement la fonction de mise à jour de progression avec en parametre le pourcentage
   if @error then return GUICtrlSetData($label_info,"erreur _FTP_ProgressDownload:"&@error)

   ;finalisation
   GUICtrlSetData($Progress_bar1,0);remise à 0 de la barre de progression
   GUICtrlSetData($label_info,"terminé")
   _FTP_Close($session_ftp);fermeture de la connexion FTP
EndFunc

Func _mise_a_jour_progression($pourcentage)
   GUICtrlSetData($Progress_bar1,$pourcentage);mise à jour de la barre de progression
   GUICtrlSetData($label_info,int($pourcentage)&"%");mise à jour du label d'information
    If _IsPressed("1B") Then Return 0 ; si la touche [Echap] est enfoncé alors on envoi 0 à la commande _FTP_ProgressDownload qui s'occupe d'annuler le téléchargement
    Return 1 ; retourne 1 à la commande _FTP_ProgressDownload pour lui dire de continuer le téléchargement
EndFunc






______________________________________________________
Mes principales réalisations: Cp (batch) et IPSvc (autoit)
Répondre en citant
Message Probleme FTP 
Pile ce qu'il me fallais, merci beaucoup a toi Cautex!



Message Probleme FTP 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch