Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
[EN-ATTENTE] Change @IP and Mask auto
Auteur Message
Répondre en citant
Message [EN-ATTENTE] Change @IP and Mask auto 
Hello,

Je rencontre un problème sur un code de mon Cmder personnalisé Okay
Si jamais vous trouvez d'ou vient le problème je serais ravi d'avoir la solution Okay

> Changement d'@IP + Mask automatisé et qui garde en mémoire la dernière adresse statique en mémoire.


Code:
@Echo Off
Title Cmder\Ping_P ## Edited By Xavier Pacio

::_> ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ // Cmder Portable ## Edited By Xavier PACIO

:Start$
Fltmc >Nul 2>&1 && (
   Goto:Next$
) || (
   Echo.
   Echo           ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
   Echo           º Note : Veuillez executer ce programme en administrateur ! º
   Echo           ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
   Echo.
   Pause > nul
   EXIT /B
   )
:Next$
Cls & Call:Menu$
Set /P "carte=* Carte reseau : "
Echo.
Set /P "choice=* DHCP/STATIC : "
If /I "%choice%" == "DHCP" (Goto:DHCP)
IF /I "%choice%" == "STATIC" (Goto:STATIC)
If /I "%choice%" == "CLOSE" (Exit /B)
Goto:Next$

:DHCP
netsh interface ipv4 set address name="%carte%" dhcp
EXIT /B
:STATIC
Call:Menu$
IF EXIST "tmp_ipaddr_ipv4.txt" (
   Set /P ipaddr=<tmp_ipaddr_ipv4.txt
   Set /P "choice=Utiliser cette adresse %ipaddr% ? ([y]/n) : "
      IF /I "%choice%" == "Y" (Goto:STATIC_2$)
      IF /I "%choice%" == "N" (Del /Q "tmp_ipaddr_ipv4.txt")
)
IF NOT EXIST "tmp_ipaddr_ipv4.txt" (
   Set /P "ipaddr=* Adresse : "
   (Echo %ipaddr%) > "tmp_ipaddr_ipv4.txt"
)
:STATIC_2$
IF EXIST "tmp_ipaddr_mask.txt" (
   Set /P mask=<tmp_ipaddr_mask.txt
   Set /P "choice=Utiliser ce masque %mask% ? ([y]/n) : "
      IF /I "%choice%" == "Y" (Goto:STATIC_3$)
      IF /I "%choice%" == "N" (Del /Q "tmp_ipaddr_mask.txt")
)
IF NOT EXIST "tmp_ipaddr_mask.txt"
   Set /P "mask=* Masque : "
   (Echo %mask%) > "tmp_ipaddr_mask.txt"
:STATIC_3$
netsh interface ipv4 set address name="%carte%" static %ipaddr% %mask%
Pause
EXIT /B

:Menu$
Cls & Echo.
Echo ______________________________________________________________
Echo.
Echo  Bienvenue sur l'assistant de changement d'adresse IP/Masque
Echo    # Program by Xavier Pacio - All right reserved.
Echo.
Echo ______________________________________________________________
Echo.
Echo  - Tapez 'Close' pour revenir a Cmder
Echo. & Echo.
Goto:Eof

::_> ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ // Cmder Portable ## Edited By Xavier PACIO


@+




______________________________________________________
Une question ? N'hésitez pas à me contacter par Message Privé ou via le topique concerné.
Visiter le site web du posteur
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message [EN-ATTENTE] Change @IP and Mask auto 
Hello,

Un petit UP pour faire remonter ce topique Okay

> Je voudrais automatiser le changement d'@IP/Masque avec la commande netsh, sauf que la 'mémoire' ne fonctionne pas correctement et je ne vois pas d'où peut venir le soucis.

@+




______________________________________________________
Une question ? N'hésitez pas à me contacter par Message Privé ou via le topique concerné.
Visiter le site web du posteur
Répondre en citant
Message [EN-ATTENTE] Change @IP and Mask auto 
Tu veut dire que toute fonctionne sauf la memoire?



Répondre en citant
Message [EN-ATTENTE] Change @IP and Mask auto 

BUG DE MéMOIRE CORRIGé!!! Wink Wink Wink Okay Okay Okay


Tu vera que sa marche Vachement Mieu Avec le Setlocal EnableDelayedExpansion et que si tu remplace tout les '%' par des '!' Okay


J'ai tout remplacé à ta place! Okay
Code:

@Echo Off
Title Cmder\Ping_P ## Edited By Xavier Pacio
setlocal EnableDelayedExpansion
::_> ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ // Cmder Portable ## Edited By Xavier PACIO

:Start$
Fltmc >Nul 2>&1 && (
   Goto:Next$
) || (
   Echo.
   Echo           ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
   Echo           º Note : Veuillez executer ce programme en administrateur ! º
   Echo           ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
   Echo.
   Pause > nul
   EXIT /B
   )
:Next$
Cls & Call:Menu$
Set /P "carte=* Carte reseau : "
Echo.
Set /P "choice=* DHCP/STATIC : "
If /I "!choice!" == "DHCP" (Goto:DHCP)
IF /I "!choice!" == "STATIC" (Goto:STATIC)
If /I "!choice!" == "CLOSE" (Exit /B)
Goto:Next$

:DHCP
netsh interface ipv4 set address name="!carte!" dhcp
EXIT /B
:STATIC
Call:Menu$
IF EXIST "tmp_ipaddr_ipv4.txt" (
   Set /P ipaddr=<tmp_ipaddr_ipv4.txt
   Set /P "choice=Utiliser cette adresse !ipaddr! ? ([y]/n) : "
      IF /I "!choice!" == "Y" (Goto:STATIC_2$)
      IF /I "!choice!" == "N" (Del /Q "tmp_ipaddr_ipv4.txt")
)
IF NOT EXIST "tmp_ipaddr_ipv4.txt" (
   Set /P "ipaddr=* Adresse : "
   (Echo !ipaddr!) > "tmp_ipaddr_ipv4.txt"
)
:STATIC_2$
IF EXIST "tmp_ipaddr_mask.txt" (
   Set /P mask=<tmp_ipaddr_mask.txt
   Set /P "choice=Utiliser ce masque !mask! ? ([y]/n) : "
      IF /I "!choice!" == "Y" (Goto:STATIC_3$)
      IF /I "!choice!" == "N" (Del /Q "tmp_ipaddr_mask.txt")
)
IF NOT EXIST "tmp_ipaddr_mask.txt"
   Set /P "mask=* Masque : "
   (Echo !mask!) > "tmp_ipaddr_mask.txt"
:STATIC_3$
netsh interface ipv4 set address name="!carte!" static !ipaddr! !mask!
Pause
EXIT /B

:Menu$
Cls & Echo.
Echo ______________________________________________________________
Echo.
Echo  Bienvenue sur l'assistant de changement d'adresse IP/Masque
Echo    # Program by Xavier Pacio - All right reserved.
Echo.
Echo ______________________________________________________________
Echo.
Echo  - Tapez 'Close' pour revenir a Cmder
Echo. & Echo.
Goto:Eof

::_> ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ // Cmder Portable ## Edited By Xavier PACIO


J'espère que ce bug ne ce manifestera plus! Okay

Bye! Okay

Et si je me mettais à faire du html? Confused



Répondre en citant
Message [EN-ATTENTE] Change @IP and Mask auto 
Bon voila la correction ULTIME!!!

Code:

@Echo Off
Title Cmder\Ping_P ## Edited By Xavier Pacio
setlocal EnableDelayedExpansion
::_> ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ // Cmder Portable ## Edited By Xavier PACIO

:Start$
Fltmc >Nul 2>&1 && (
   Goto:Next$
) || (
   Echo.
   Echo           ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
   Echo           º Note : Veuillez executer ce programme en administrateur ! º
   Echo           ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
   Echo.
   Pause > nul
   EXIT /B
   )
:Next$
Cls & Call:Menu$
Set /P "carte=* Carte reseau : "
Echo.
Set /P "choice=* DHCP/STATIC : "
If /I "!choice!" == "DHCP" (Goto:DHCP)
IF /I "!choice!" == "STATIC" (Goto:STATIC)
If /I "!choice!" == "CLOSE" (Exit /B)
Goto:Next$

:DHCP
netsh interface ipv4 set address name="!carte!" dhcp
EXIT /B
:STATIC
Call:Menu$
IF EXIST "tmp_ipaddr_ipv4.txt" (
   for /f "usebackq tokens=*" %%i in ("tmp_ipaddr_ipv4.txt") do set ipaddr=%%i
   Set/P "choice=Utiliser cette adresse !ipaddr! ? ([y]/n) : "
   IF /I "!choice!"=="Y" Goto :STATIC_2$
   IF /I "!choice!"=="N" Del /Q "tmp_ipaddr_ipv4.txt"
)
IF NOT EXIST "tmp_ipaddr_ipv4.txt" (
   Set/P "ipaddr=* Adresse : "
   Echo;!ipaddr!>"tmp_ipaddr_ipv4.txt"
)
:STATIC_2$
IF EXIST "tmp_ipaddr_mask.txt" (
   for /f "usebackq tokens=*" %%i in ("tmp_ipaddr_mask.txt") do set mask=%%i
   Set/P "choice=Utiliser ce masque !mask! ? ^([y]/n^) : "
   IF /I "!choice!"=="Y" Goto :STATIC_3$
   IF /I "!choice!"=="N" Del /Q "tmp_ipaddr_mask.txt"
)
IF NOT EXIST "tmp_ipaddr_mask.txt" (
   Set /P "mask=* Masque : "
   Echo;!mask!>"tmp_ipaddr_mask.txt"
)
:STATIC_3$
netsh interface ipv4 set address name="!carte!" static !ipaddr! !mask!
Pause
EXIT /B

:Menu$
Cls
Echo.
Echo ______________________________________________________________
Echo.
Echo  Bienvenue sur l'assistant de changement d'adresse IP/Masque
Echo    # Program by Xavier Pacio - All right reserved.
Echo.
Echo ______________________________________________________________
Echo.
Echo  - Tapez 'Close' pour revenir a Cmder
Echo. & Echo.
Goto :Eof

::_> ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ // Cmder Portable ## Edited By Xavier PACIO


N'oublie pas le p'tit Plus \/ Okay

Bye! Okay



Message [EN-ATTENTE] Change @IP and Mask auto 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch