Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
[R] Espace insérer mais introuvable
Auteur Message
Répondre en citant
Message [R] Espace insérer mais introuvable 
Bonsoir,

le script fonctionnait très bien, j'ai voulu l'éditer avec un éditeur DOS et depuis il ne fonctionne plus...

Code:

@ECHO off
setlocal
COLOR 0E
TITLE TeamViewer Maker 1.0
PUSHD %~dp0

SET SZ=".\bin\7za.exe"
SET SFX=".\bin\TeamViewer.sfx"
SET CFG=".\bin\TeamViewer.cfg"
IF EXIST "svcpack"  RMDIR "svcpack" /s /q
IF EXIST "temp"  RMDIR "temp" /s /q
SET CMD7z=-mx=8
SET I3=I386\SVCPACK.INF,SetupHotfixesToRun,AddProgram
SET BLD=builddate=%date%
SET DESC=description=TeamViewer
SET URL=website=https://www.teamviewer.com/
SET LNG=language=Multi
SET LOG=".\output\_log.txt"
SET SEP=-------------------------
SET SUC=was successfully created.

::If you want to create a nLite/RVMi Addon, set this variable to 1:
SET addon=0

:: If you want to add a reg file for custom, set this variable to 1
SET regfile=0

:ChoiceLang
CLS
ECHO                        Welcome to TeamViewer Multi Maker
echo.
ECHO      Wich language do you want to use in this script ?
echo.           Note: TeamViewer will be installed in the language of the system.
echo.
ECHO                  - English  - tap 1 then ENTER
ECHO                  - Francais - tap 2 then ENTER
::echo - Romana - tap 3 then ENTER
::echo - Deutsch - tap 4 then ENTER
::echo - Italiano - tap 5 then ENTER
::echo - Portugues-Brasil - tap 6 then ENTER
echo.
ECHO %SEP%%SEP%%SEP%
SET /p lang=
IF /i "%lang%"=="1" (set lng=en && GOTO :Download)
IF /i "%lang%"=="2" (set lng=fr && GOTO :Download)
::if /I "%lang%" == "3" (set lng=RO && GOTO :Download)
::if /I "%lang%" == "4" (set lng=DE && GOTO :Download)
::if /I "%lang%" == "5" (set lng=IT && GOTO :Download)
::if /I "%lang%" == "6" (set lng=PTBR && GOTO :Download)
GOTO :ChoiceLang

:Download
MODE con cols=90 lines=25
CLS
ECHO %SEP%%SEP%%SEP%
echo.
ECHO            Do you want to download the latest installers from TeamViewer ?
ECHO               They will be downloaded in the "download" folder.
ECHO             You can also copy them in this folder to work offline
echo.
ECHO %SEP%%SEP%%SEP%
echo.
ECHO 1 - Yes (previous installers will be deleted).                   - tap 1 then ENTER
ECHO 2 - No (The latest version should be in the download directory). - tap 2 then ENTER
echo.
SET /p dl=
IF /i "%dl%"=="1" (del /Q .\download\TeamViewer_Setup*.exe && GOTO :Dispatch)
IF /i "%dl%"=="2" (goto :Dispatch)
GOTO :Download

:Dispatch
CLS
IF %lang%==1 (goto :TV_EN)
IF %lang%==2 (goto :TV_FR)

:TV_EN
SET exe=TeamViewer_Setup_%lng%.exe
SET ex=TeamViewer_%lng%.exe
SET sfxname=SFX_TeamViewer_EN
SET name=TeamViewer_EN
GOTO :eof

:TV_FR
SET exe=TeamViewer_Setup_%lng%.exe
:: En mettant un echo %exe%, l'espace est affiché >> [b]TeamViewer_Setup_%lng% .exe[/b]
SET ex=TeamViewer_%lng%.exe
SET sfxname=SFX_TeamViewer_FR
SET name=TeamViewer_FR
GOTO :eof

:WGET
CLS
IF EXIST ".\download\%exe%"  GOTO :downloaded else ( goto :continue_DL )
:continue_DL
ECHO Please Wait while Installer %exe% setup is downloaded...
".\bin\wget.exe" --no-check-certificate -q -P .\download "https://downloadeu2.teamviewer.com/download/%exe%"


L'erreur est ici:
Code:
SET exe=TeamViewer_Setup_%lng%.exe
, il s'affiche:
Code:
SET exe=TeamViewer_Setup_%lng% .exe


il y a un espace lors de l'exécution pourtant on ne voit rien....



Comment corriger le problème ?

Merci



Dernière édition par Owned le Mar 26 Juil 2016 - 02:47; édité 1 fois
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message [R] Espace insérer mais introuvable 
Lignes 45 46 :
Code:
IF /i "%lang%"=="1" (set lng=en && GOTO :Download)
IF /i "%lang%"=="2" (set lng=fr && GOTO :Download)


enlève les espaces avant les "&&" Okay




______________________________________________________
Cordialement,
Hugo, qui adore programmer, jouer à Minecraft, ZT2 et FSX.
Boutons-liens :
Visiter le site web du posteur Skype
Répondre en citant
Message [R] Espace insérer mais introuvable 
Merci, impeccable !



Message [R] Espace insérer mais introuvable 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch