Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
clé de chiffrage
Auteur Message
Répondre en citant
Message clé de chiffrage 
salut a tous , j'aurais besoins d'aide , ou plutot d'un example de batch , pour creer une clé de chiffrage (simple pout l'instant et si possible apres une asymétrique )
je sais a peu pres comment faire mais la forme m'échappe !
merci Mr. Green




______________________________________________________
baaaatch c'est moi !!!
Skype
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message clé de chiffrage 
Salut Mr. Green

Comme ça je pense :

Code:
@echo off
title By Flammrock
setlocal enabledelayedexpansion



call :generateKey 30
echo;!key!





pause>nul
exit
:generateKey <nb>
  set charset=0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz-_
  call :length "%charset%"
  set key=
  for /l %%a in (0,1,%~1) do (
    set /a r=!random!%%%length%
   for %%b in ("!r!,1") do set key=!key!!charset:~%%~b!
  )
goto:eof
:length <variable>
  for /f "tokens=1* delims=[]" %%a in ('"%comspec% /u /c echo:%~1|more|find /n /v """') do set /a "length=%%a-4"
goto:eof





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message clé de chiffrage 
euuuuu là tu m'as tué Shocked

désolé j'ai rien pigé Embarassed

tu pourrais mettre des " ::explications " stp Mr. Green
merci




______________________________________________________
baaaatch c'est moi !!!
Skype
Répondre en citant
Message clé de chiffrage 
batch.bat a écrit:
euuuuu là tu m'as tué Shocked

désolé j'ai rien pigé Embarassed

tu pourrais mettre des " ::explications " stp Mr. Green
merci

A oui d'accord, TOUT DE SUITE CHEF xD

Donc reprenons depuis le début :

Code:
@echo off
title By Flammrock
setlocal enabledelayedexpansion
 
 
:: On appelle la "fonction" generateKey et on lui passe en argument 30 qui correspond a la longueur de la clé soit 30 caractères
call :generateKey 30


:: On affiche la valeur de la variable key
echo;!key!
 
 
 
 
 
pause>nul
exit


:: Le <nb> ne fait pas buguer le script, il sert juste a informer au programmeur les arguments passés ici c'est un simple nombre
:generateKey <nb>


  :: On définit le charset qui correspond a l'ensemble des caractères présents dans les clés générées
  :: la variable charset nous sert tout simplement de briques pour notre clé
  set charset=0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz-_



  :: On appelle la "fontion" length et on lui passe en argument la variable charset
  :: Cette fonction met son résultat dans la variable length
  :: Celle-ci sert a compté le nombre de caractères dans la variable charset
  call :length "%charset%"



  :: Avant de continuer, plus loin
  :: Je vais expliquer le but de tout ce bloc :
   
      :: On compte le nombre de caractères dans la variable charset
      :: Puis on défini une variable avec un nom quelconque et on lui met le contenu de la variable random (c'est une variable qui ce met a jour continuellement qui correspond a un nombre choisi au hasard)
      :: qui est défini sur l'intervalle [0,%length%] (la variable length correspond au nombre de caractères de la variable charset)
      :: Ensuite on récupère le caractère de la variable charset étant a la position du contenu de la variable contenant un nombre random compris entre 0 et %length%
      :: Pour finir on incrémente la variable key étant défini au préalable avant comme étant vide le caractère du charset choisi au hasard par le précédent procédé


  :: On déclare la variable key comme étant vide
  set key=


  :: On fait %~1 tour, le code contenu dans cette boucle for va se répété %~1 fois (cela correspond au nombre 30 que l'on a passé en argument au début du script)
  for /l %%a in (0,1,%~1) do (


    :: On associe a la variable r un nombre random compris entre 0 et le nombre de caractère du charset
    set /a r=!random!%%%length%

   :: on construit ici notre variable key en l'incrémentant uniquement du !r!éme caractère de la variable charset
   for %%b in ("!r!,1") do set key=!key!!charset:~%%~b!


  )

:: On retourne d'où on est parti
goto:eof


:length <variable>

  :: En utilisant "find", on compte le nombre de caractères de %~1
  for /f "tokens=1* delims=[]" %%a in ('"%comspec% /u /c echo:%~1|more|find /n /v """') do set /a "length=%%a-4"


goto:eof


J'espère que j'ai bien expliqué
Dis-moi ce que tu n'as pas trop compris au pire
Parce que moi je code comme ça tout les jours donc j'ai assimilé des trucs complexes et ça me paraît très simple (pour moi ce code est un code très simple)



Sinon juste pour le fun j'ai fait ça :

Code:
@echo off
title KEY GENERATOR ^| Créé Flammrock
chcp 28591 > nul
setlocal enabledelayedexpansion
mode con cols=134 lines=18


for %%a in (1 2 3 4 3 2 1 1 2 4 3 2 1 2 1 3 4 2 1 2 3 4 1 2 3 4 3 2 1 1 2 4 3 2 1 2 1 3 4 2 1 2 3 4 1 2 3 4 3 2 1 1 2 4 3 2 1 2 1 3 4 2 1 2 3 4) do (
  call :anim %%a
  echo;     Chargement..
  for /l %%b in (0,1,6) do @ping localhost -n 1 >nul
)
cls&call :anim 4
echo;     Génération de 200 clés..
echo;     Veuillez patienter..

echo;
(
  for /l %%a in (0,1,200) do (
    set /a i=!random!%%50
    call :generateKey !i!
    echo;key_%%a = !key!
  )
)> keys.ini
start keys.ini
cls&call :anim 4
echo;     Fin de la génération ^^!^^!
for %%a in (1 2 3 4 3 2 1 1 2 4 3 2 1 2 1 3 4 2 1 2 3 4 1 2 3 4 3 2 1 1 2 4 3 2 1 2 1 3 4 2 1 2 3 4 1 2 3 4 3 2 1 1 2 4 3 2 1 2 1 3 4 2 1 2 3 4) do (
  call :anim %%a
  echo;     Petite animation de fin xD
  for /l %%b in (0,1,6) do @ping localhost -n 1 >nul
)
pause>nul
exit
:generateKey <nb>
  set charset=0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz-_
  call :length "%charset%"
  set key=
  for /l %%a in (0,1,%~1) do (
    set /a r=!random!%%%length%
   for %%b in ("!r!,1") do set key=!key!!charset:~%%~b!
  )
goto:eof
:length <variable>
  for /f "tokens=1* delims=[]" %%a in ('"%comspec% /u /c echo:%~1|more|find /n /v """') do set /a "length=%%a-4"
goto:eof
:anim <img>
cls
if "%~1"=="1" (
  echo;
  echo;   /$$   /$$ /$$$$$$$$ /$$     /$$        /$$$$$$  /$$$$$$$$ /$$   /$$ /$$$$$$$$ /$$$$$$$   /$$$$$$  /$$$$$$$$ /$$$$$$  /$$$$$$$
  echo;  ^| $$  /$$/^| $$_____/^|  $$   /$$/       /$$__  $$^| $$_____/^| $$$ ^| $$^| $$_____/^| $$__  $$ /$$__  $$^|__  $$__//$$__  $$^| $$__  $$
  echo;  ^| $$ /$$/ ^| $$       \  $$ /$$/       ^| $$  \__/^| $$      ^| $$$$^| $$^| $$      ^| $$  \ $$^| $$  \ $$   ^| $$  ^| $$  \ $$^| $$  \ $$
  echo;  ^| $$$$$/  ^| $$$$$     \  $$$$/        ^| $$ /$$$$^| $$$$$   ^| $$ $$ $$^| $$$$$   ^| $$$$$$$/^| $$$$$$$$   ^| $$  ^| $$  ^| $$^| $$$$$$$/
  echo;  ^| $$  $$  ^| $$__/      \  $$/         ^| $$^|_  $$^| $$__/   ^| $$  $$$$^| $$__/   ^| $$__  $$^| $$__  $$   ^| $$  ^| $$  ^| $$^| $$__  $$
  echo;  ^| $$\  $$ ^| $$          ^| $$          ^| $$  \ $$^| $$      ^| $$\  $$$^| $$      ^| $$  \ $$^| $$  ^| $$   ^| $$  ^| $$  ^| $$^| $$  \ $$
  echo;  ^| $$ \  $$^| $$$$$$$$    ^| $$          ^|  $$$$$$/^| $$$$$$$$^| $$ \  $$^| $$$$$$$$^| $$  ^| $$^| $$  ^| $$   ^| $$  ^|  $$$$$$/^| $$  ^| $$
  echo;  ^|__/  \__/^|________/    ^|__/           \______/ ^|________/^|__/  \__/^|________/^|__/  ^|__/^|__/  ^|__/   ^|__/   \______/ ^|__/  ^|__/
  echo;
  echo; 
)                                                                                                                     
if "%~1"=="2" (
  echo;
  echo;  $$\   $$\ $$$$$$$$\ $$\     $$\        $$$$$$\  $$$$$$$$\ $$\   $$\ $$$$$$$$\ $$$$$$$\   $$$$$$\ $$$$$$$$\  $$$$$$\  $$$$$$$\ 
  echo;  $$ ^| $$  ^|$$  _____^|\$$\   $$  ^|      $$  __$$\ $$  _____^|$$$\  $$ ^|$$  _____^|$$  __$$\ $$  __$$\\__$$  __^|$$  __$$\ $$  __$$\
  echo;  $$ ^|$$  / $$ ^|       \$$\ $$  /       $$ /  \__^|$$ ^|      $$$$\ $$ ^|$$ ^|      $$ ^|  $$ ^|$$ /  $$ ^|  $$ ^|   $$ /  $$ ^|$$ ^|  $$ ^|
  echo;  $$$$$  /  $$$$$\      \$$$$  /        $$ ^|$$$$\ $$$$$\    $$ $$\$$ ^|$$$$$\    $$$$$$$  ^|$$$$$$$$ ^|  $$ ^|   $$ ^|  $$ ^|$$$$$$$  ^|
  echo;  $$  $$^<   $$  __^|      \$$  /         $$ ^|\_$$ ^|$$  __^|   $$ \$$$$ ^|$$  __^|   $$  __$$^< $$  __$$ ^|  $$ ^|   $$ ^|  $$ ^|$$  __$$^<
  echo;  $$ ^|\$$\  $$ ^|          $$ ^|          $$ ^|  $$ ^|$$ ^|      $$ ^|\$$$ ^|$$ ^|      $$ ^|  $$ ^|$$ ^|  $$ ^|  $$ ^|   $$ ^|  $$ ^|$$ ^|  $$ ^|
  echo;  $$ ^| \$$\ $$$$$$$$\     $$ ^|          \$$$$$$  ^|$$$$$$$$\ $$ ^| \$$ ^|$$$$$$$$\ $$ ^|  $$ ^|$$ ^|  $$ ^|  $$ ^|    $$$$$$  ^|$$ ^|  $$ ^|
  echo;  \__^|  \__^|\________^|    \__^|           \______/ \________^|\__^|  \__^|\________^|\__^|  \__^|\__^|  \__^|  \__^|    \______/ \__^|  \__^|
  echo;
  echo;
)
if "%~1"=="3" (
  echo;
  echo;    __    __  ________  __      __         ______   ________  __    __  ________  _______    ______  ________   ______   _______ 
  echo;  ^|  \  /  \^|        \^|  \    /  \       /      \ ^|        \^|  \  ^|  \^|        \^|       \  /      \^|        \ /      \ ^|       \
  echo;  ^| $$ /  $$^| $$$$$$$$ \$$\  /  $$      ^|  $$$$$$\^| $$$$$$$$^| $$\ ^| $$^| $$$$$$$$^| $$$$$$$\^|  $$$$$$\\$$$$$$$$^|  $$$$$$\^| $$$$$$$\
  echo;  ^| $$/  $$ ^| $$__      \$$\/  $$       ^| $$ __\$$^| $$__    ^| $$$\^| $$^| $$__    ^| $$__^| $$^| $$__^| $$  ^| $$   ^| $$  ^| $$^| $$__^| $$
  echo;  ^| $$  $$  ^| $$  \      \$$  $$        ^| $$^|    \^| $$  \   ^| $$$$\ $$^| $$  \   ^| $$    $$^| $$    $$  ^| $$   ^| $$  ^| $$^| $$    $$
  echo;  ^| $$$$$\  ^| $$$$$       \$$$$         ^| $$ \$$$$^| $$$$$   ^| $$\$$ $$^| $$$$$   ^| $$$$$$$\^| $$$$$$$$  ^| $$   ^| $$  ^| $$^| $$$$$$$\
  echo;  ^| $$ \$$\ ^| $$_____     ^| $$          ^| $$__^| $$^| $$_____ ^| $$ \$$$$^| $$_____ ^| $$  ^| $$^| $$  ^| $$  ^| $$   ^| $$__/ $$^| $$  ^| $$
  echo;  ^| $$  \$$\^| $$     \    ^| $$           \$$    $$^| $$     \^| $$  \$$$^| $$     \^| $$  ^| $$^| $$  ^| $$  ^| $$    \$$    $$^| $$  ^| $$
  echo;   \$$   \$$ \$$$$$$$$     \$$            \$$$$$$  \$$$$$$$$ \$$   \$$ \$$$$$$$$ \$$   \$$ \$$   \$$   \$$     \$$$$$$  \$$   \$$
  echo;
  echo;                                                                                                               
)
if "%~1"=="4" (
  echo;
  echo;   __    __  ________  __      __         ______   ________  __    __  ________  _______    ______   ________  ______   _______ 
  echo;  /  ^|  /  ^|/        ^|/  \    /  ^|       /      \ /        ^|/  \  /  ^|/        ^|/       \  /      \ /        ^|/      \ /       \
  echo;  $$ ^| /$$/ $$$$$$$$/ $$  \  /$$/       /$$$$$$  ^|$$$$$$$$/ $$  \ $$ ^|$$$$$$$$/ $$$$$$$  ^|/$$$$$$  ^|$$$$$$$$//$$$$$$  ^|$$$$$$$  ^|
  echo;  $$ ^|/$$/  $$ ^|__     $$  \/$$/        $$ ^| _$$/ $$ ^|__    $$$  \$$ ^|$$ ^|__    $$ ^|__$$ ^|$$ ^|__$$ ^|   $$ ^|  $$ ^|  $$ ^|$$ ^|__$$ ^|
  echo;  $$  $$^<   $$    ^|     $$  $$/         $$ ^|/    ^|$$    ^|   $$$$  $$ ^|$$    ^|   $$    $$^< $$    $$ ^|   $$ ^|  $$ ^|  $$ ^|$$    $$^<
  echo;  $$$$$  \  $$$$$/       $$$$/          $$ ^|$$$$ ^|$$$$$/    $$ $$ $$ ^|$$$$$/    $$$$$$$  ^|$$$$$$$$ ^|   $$ ^|  $$ ^|  $$ ^|$$$$$$$  ^|
  echo;  $$ ^|$$  \ $$ ^|_____     $$ ^|          $$ \__$$ ^|$$ ^|_____ $$ ^|$$$$ ^|$$ ^|_____ $$ ^|  $$ ^|$$ ^|  $$ ^|   $$ ^|  $$ \__$$ ^|$$ ^|  $$ ^|
  echo;  $$ ^| $$  ^|$$       ^|    $$ ^|          $$    $$/ $$       ^|$$ ^| $$$ ^|$$       ^|$$ ^|  $$ ^|$$ ^|  $$ ^|   $$ ^|  $$    $$/ $$ ^|  $$ ^|
  echo;  $$/   $$/ $$$$$$$$/     $$/            $$$$$$/  $$$$$$$$/ $$/   $$/ $$$$$$$$/ $$/   $$/ $$/   $$/    $$/    $$$$$$/  $$/   $$/
  echo;
  echo;
)
goto:eof





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message clé de chiffrage 
tres bien tout ça merci !
CEPENDANT j'ai encore une petite question Embarassed comment on s'en sert ?! Mr. Green




______________________________________________________
baaaatch c'est moi !!!
Skype
Répondre en citant
Message clé de chiffrage 
batch.bat a écrit:
tres bien tout ça merci !
CEPENDANT j'ai encore une petite question Embarassed comment on s'en sert ?! Mr. Green



Ba :

Code:
call :generateKey 10


Tu appelle la "fonction" generateKey et tu lui passe en argument la longueur de la clé.
Ici par exemple je génère une clé de 10 caractères

Et ensuite pour pouvoir utilise la clé :

Code:
echo;!key!

(L'output de la fonction se met automatiquement dans la variable key)
Si tu veux générer 2 clés par exemple :

Code:
call :generateKey 10
set key1=!key!
call :generateKey 10
set key2=!key!

echo;!key1!
echo;!key2!



Vérifie bien sûr de mettre le :
Code:
setlocal enabledelayedexpansion

au début de ton script



Ce qui donne au final ceci :
Code:
@echo off
setlocal enabledelayedexpansion
 
 
 
call :generateKey 10
set key1=!key!
call :generateKey 10
set key2=!key!
 
echo;!key1!
echo;!key2!
 
 
 
pause>nul
exit
:generateKey <nb>
  set charset=0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz-_
  call :length "%charset%"
  set key=
  for /l %%a in (0,1,%~1) do (
    set /a r=!random!%%%length%
   for %%b in ("!r!,1") do set key=!key!!charset:~%%~b!
  )
goto:eof
:length <variable>
  for /f "tokens=1* delims=[]" %%a in ('"%comspec% /u /c echo:%~1|more|find /n /v """') do set /a "length=%%a-4"
goto:eof





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message clé de chiffrage 
désolé j'ai du mal formuler ,
c'est plutot comment on fait pour l'utiliser pour chiffrer un message ?




______________________________________________________
baaaatch c'est moi !!!
Skype
Répondre en citant
Message clé de chiffrage 
batch.bat a écrit:
désolé j'ai du mal formuler ,
c'est plutot comment on fait pour l'utiliser pour chiffrer un message ?


A d'accord, tu veux chiffrer un message avec une clé Mr. Green
Ba il faut faire tout un système de chiffrage avec comme fonctionnement une clé

Je viens de trouver une méthode pour faire ce que tu veux.
Un indice pour toi si tu veux tenter de faire le système : "Il faut utiliser concrètement la clé"

Aller je code sa et je reviens, enfin je code ça dès que je peux genre vers 1h du matin




______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message clé de chiffrage 
Flammrock a écrit:

Un indice pour toi si tu veux tenter de faire le système : "Il faut utiliser concrètement la clé"



merci , je sais deja a peu pres comment faire mais je n'ai absolument aucune idée de comment le faire en batch Rolling Eyes
et puis tu sais bien que je n'apprend bien qu'en ayant un code de support Mr. Green
merciii




______________________________________________________
baaaatch c'est moi !!!
Skype
Répondre en citant
Message clé de chiffrage 
en fait ce n'est pas seulement pour un message donc il faudrais que ça puisse chiffrer beaucoup beaucoup de caracteres
Okay




______________________________________________________
baaaatch c'est moi !!!
Skype
Message clé de chiffrage 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch