Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
[R] décomposer des mots en lettre
Auteur Message
Répondre en citant
Message [R] décomposer des mots en lettre 
bonjour a tous !!!

j'ai créé un code qui permet de créer un code ( Mort de Rire ) :
Code:
@echo off

echo. voulez vous ecrire un programe pour cmd (1) ou notepad (2)
set /p choix= 1 / 2 :
if %choix%==1 set prog=cmd
if %choix%==2 set prog=notepad
echo Set variable=CreateObject("WScript.Shell" ) >auto.vbs
echo variable.Run("C:\WINDOWS\System32\%prog%.exe" ) >>auto.vbs
echo wscript.sleep 100 >>auto.vbs

set /p att= entrez le nombre de secondes entre les entrees

echo. pour entrer des fonctions telle que ctrl , alt ... consultez le guide ici : https://msdn.microsoft.com/fr-fr/library/office/gg278655.aspx
echo. pour sortir fermez la fenetre
echo. pour mettre un espace dans votre programe faites tous simplement un espace
echo. pour plus de coolitude entrez les mots lettres par lettres
:ecrire
set /p lettr= :
echo variable.SendKeys ("%lettr%" ) >>auto.vbs
echo wscript.sleep %att% >>auto.vbs
goto ecrire

:fin
exit



on entre les touches a exécuter et il créé le code vbs ( visual basic script ) qui exécute ces touches comme si un clavier les entraient
en gros on entre les touches pour qu'un clavier virtuel les exécutes
et ce que je voudrais c'est qu'on entre les mots en entier et que le code se remplisse lettre par lettre , MAIS sauf pour les mots entourés de { } ex: {enter} ; {bs} ; etc


car quand il y a { } c'est une touche speciale , ex: entrer = {enter} , retour arriere = {bs} ; etc ,
si le code vous interesse , il y a toutes les touches possibles ici : https://msdn.microsoft.com/fr-fr/library/office/gg278655.aspx



Dernière édition par batch.bat le Mar 2 Mai 2017 - 17:52; édité 1 fois

______________________________________________________
baaaatch c'est moi !!!
Skype
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message [R] décomposer des mots en lettre 
Alors pour faire ça tu peux faire comme ça :

Code:
@echo off
Setlocal enableextensions enabledelayedexpansion
 
set /p s=^>
call :SepareString s
echo;!s!
pause
 
 
 
:SepareString <String>
  set a=!%~1!
  set b=%~1
  set %b%=
  for /f "tokens=1* delims=[]" %%a in ('"%comspec% /u /c echo:%a%|more|find /n /v """') do set /a "length=%%a-4"
  for /l %%a in (0,1,!length!) do set %b%=!%b%! !a:~%%a,1!
  set c=!%b%!
  set %b%=%c:~1%
goto :eof




Sinon je poste ici la version 5 du programme :


Code:
::#~####### HEAD
  @echo off
  title VKBM - VirtualKeyBoardMaker ^| By Batch.bat and Flammrock
  chcp 28591 > nul
  Setlocal enableextensions enabledelayedexpansion
  mode con lines=30 cols=80
  call :BATBOX
  set batbox="%temp%\batbox.exe"
  color f0
  set prog=cmd
::#~####### HEAD



::#~####### BODY
  :body
  call :Welcome
  call :menu
 
  :CMD
    set prog=cmd
   set mode=1
  goto :CREATE
  :NOTEPAD
    set prog=notepad
   set mode=1
  goto :CREATE
  :LIBERTY
    set prog=none
   set mode=0
  goto :CREATE
  :ABOUT
    call :aboutMenu
  :EXIT
  exit
 
  :CREATE
    set totalLines=0
   if "%mode%"=="1" (
     (
       !AUTO!Set v=CreateObject^("WScript.Shell"^)
       !AUTO!v.Run^("C:\WINDOWS\System32\%prog%.exe"^)
       !AUTO!wscript.sleep 100
     )> "auto.vbs"
   ) else (
     (
       !AUTO!Set v=CreateObject^("WScript.Shell"^)
      !AUTO!'MODE LIBRE
       !AUTO!wscript.sleep 100
     )> "auto.vbs"
   )
   :CREATE_BODY
    call :Welcome
   call :CREATE_MENU
    :F_1
     call :Welcome
     set sdisplay=
     set s=
     %batbox% /g 2 7 /d "[" /c 0xfc /d "Info" /c 0xf0 /d "] : Appuyez sur '" /c 0xf2 /d "&" /c 0xf0 /d "' pour afficher le menu des caractères spéciaux"
     :F_1s
       set asciiN=false
       %batbox% /g 0 9 /d ">!sdisplay!"
       %batbox% /k
      
      if "%errorlevel%"=="233" (
        rem é
        set asciiN=true
        set s=!s!é
          set sdisplay=!sdisplay!é
      )
      if "%errorlevel%"=="232" (
        rem è
        set asciiN=true
        set s=!s!è
          set sdisplay=!sdisplay!è
      )
      if "%errorlevel%"=="231" (
        rem ç
        set asciiN=true
        set s=!s!ç
          set sdisplay=!sdisplay!ç
      )
      if "%errorlevel%"=="479" (
        rem à
        set asciiN=true
        set s=!s!à
          set sdisplay=!sdisplay!à
      )
      
      if "!asciiN!"=="true" (
        %batbox% /g 0 9 /d ">!sdisplay!"
      )
      
      if not "!asciiN!"=="true" (
        if not "%errorlevel%"=="38" (
           if not "%errorlevel%"=="0" (
             if "%errorlevel%"=="13" goto :F_1e
             if "%errorlevel%"=="8" (
               if not "!s!"=="" (
                set s=!s:~0,-1!
                set sdisplay=!sdisplay:~0,-1!
                  %batbox% /g 0 9 /d ">!sdisplay! "
                %batbox% /g 0 9 /d ">!sdisplay!"
              )
             ) else (
               cmd /c exit %errorlevel%
               set filter=!=exitcodeAscii!
               if "!filter!"=="^!" set filter=^^!
               set s=!s!!filter!
                set sdisplay=!sdisplay!!=exitcodeAscii!
             )
           )
        ) else (
          rem é -------------------->
             %batbox% /g 0 27 /d "+-------+"
             %batbox% /g 0 28 /d "|   é   |"
             %batbox% /g 0 29 /d "+-------+"
           rem <-------------------
          rem è -------------------->
             %batbox% /g 10 27 /d "+-------+"
             %batbox% /g 10 28 /d "|   è   |"
             %batbox% /g 10 29 /d "+-------+"
           rem <-------------------
          rem à -------------------->
             %batbox% /g 20 27 /d "+-------+"
             %batbox% /g 20 28 /d "|   à   |"
             %batbox% /g 20 29 /d "+-------+"
           rem <-------------------
   
           rem btn_1_RETOUR ---------->
             %batbox% /g 64 25 /d "+-------------+"
             %batbox% /g 64 26 /d "|             |"
             %batbox% /g 64 27 /d "|    RETOUR   |"
             %batbox% /g 64 28 /d "|             |"
             %batbox% /g 64 29 /d "+-------------+"
           rem <-------------------
   
           :MENU-subopt-_listen
             for /f "tokens=1,2 delims=:" %%a in ('%batbox% /M') do (
                set y=%%b
                set x=%%a
              )
             rem é -->
               if %x% GEQ 0 if %y% GEQ 25 if %x% LEQ 9 if %y% LEQ 29 ( set s=!s!é&set sdisplay=!sdisplay!é&%batbox% /g 0 9 /d ">!sdisplay!" )
             rem <--
           rem è -->
               if %x% GEQ 10 if %y% GEQ 25 if %x% LEQ 19 if %y% LEQ 29 ( set s=!s!è&set sdisplay=!sdisplay!è&%batbox% /g 0 9 /d ">!sdisplay!" )
             rem <--
           rem à -->
               if %x% GEQ 20 if %y% GEQ 25 if %x% LEQ 29 if %y% LEQ 29 ( set s=!s!à&set sdisplay=!sdisplay!à&%batbox% /g 0 9 /d ">!sdisplay!" )
             rem <--
           rem btn_1 "RETOUR" -->
               if %x% GEQ 64 if %y% GEQ 25 if %x% LEQ 79 if %y% LEQ 29 (
               for /l %%a in (1,1,5) do (
                set /a tmpa=%%a+24
                %batbox% /g 0 !tmpa! /d "                                                                               "
              )
               goto :F_1s
             )
             rem <--
           goto :MENU-subopt-_listen
        )
      )
     goto :F_1s
     :F_1e
     set tvl=!s!
     set s=!s: =IIESPACEDKFSLJDHSHDSJKLII!
     set s=!s:?=IIPOINTIDKFSLJDHSHDSJKLII!
     set s=%s:!=IIPOINTEDKFSLJDHSHDSJKLII%
      call :SepareString s
      for %%a in (!s!) do (
       set l=%%a
       if "!l!"=="IIESPACEDKFSLJDHSHDSJKLII" set "l= "
      if "!l!"=="IIPOINTIDKFSLJDHSHDSJKLII" set "l=?"
      if "!l!"=="IIPOINTEDKFSLJDHSHDSJKLII" (
        set "l=^^^!"
        (
            !AUTO!v.SendKeys^("!l:~1!"^)
            !AUTO!wscript.sleep 200
         )>> "auto.vbs"
      ) else (
        (
            !AUTO!v.SendKeys^("!l!"^)
            !AUTO!wscript.sleep 200
         )>> "auto.vbs"
      )
      )
     (
        !AUTO!v.SendKeys^("~"^)
        !AUTO!wscript.sleep 200
     )>> "auto.vbs"
     set /a totalLines+=1
     set cl_!totalLines!=!length!
     set vl_!totalLines!=%tvl%
   goto :CREATE_BODY
   :F_2
     call :Welcome
     if not "!totalLines!"=="0" (
       set l=0
       for /f "tokens=*" %%a in (' type "%temp%\visu.bat" ') do (
         set /a l+=1
        set lb_!l!=%%a
       )
       for %%b in (!totalLines!) do set /a al=!l!-1
       del /q "%temp%\visu.bat"
       for /l %%a in (1,1,!al!) do (
         (
          !AUTO!!lb_%%a!
        )>> "%temp%\visu.bat"
       )
       set l=0
       for /f "tokens=*" %%a in (' type "auto.vbs" ') do (
         set /a l+=1
        set lb_!l!=%%a
       )
       for %%b in (!totalLines!) do set /a al=!l!-!cl_%%b!*2-2
       del /q "auto.vbs"
       for /l %%a in (1,1,!al!) do (
         (
          !AUTO!!lb_%%a!
        )>> "auto.vbs"
       )
       set /a totalLines-=1
     ) else (
       %batbox% /c 0xf0 /d "[" /c 0xfc /d "ERROR" /c 0xf0 /d "] : Il n'y a aucune ligne ^^!"
        rem btn_4_RETOUR ---------->
         %batbox% /g 64 25 /d "+-------------+"
         %batbox% /g 64 26 /d "+             +"
         %batbox% /g 64 27 /d "+    RETOUR   +"
         %batbox% /g 64 28 /d "+             +"
         %batbox% /g 64 29 /d "+-------------+"
       rem <-------------------
      :CREATE_MENU_-sub-_listen
        for /f "tokens=1,2 delims=:" %%a in ('%batbox% /M') do (
         set y=%%b
         set x=%%a
        )
        rem btn_4 "RETOUR" -->
         if %x% GEQ 64 if %y% GEQ 25 if %x% LEQ 79 if %y% LEQ 29 ( goto :CREATE_BODY )
        rem <--
      goto :CREATE_MENU_-sub-_listen
     )
   goto :CREATE_BODY
   :F_3
     call :Welcome
     if "%mode%"=="1" (
       start auto.vbs
     ) else (
       :F_3s
         %batbox% /k_
         cmd /c exit %errorlevel%
         set filter=!=exitcodeAscii!
        %batbox% /g 10 7 /d "Vous devez appuyer sur la lettre 'e' pour exécuter votre code !"
        %batbox% /g 10 8 /d"Touche pressé : !filter!"
         if "!filter!"=="e" start auto.vbs&goto :CREATE_BODY
      goto :F_3s
     )
   goto :CREATE_BODY
   :F_4
     echo;@echo off> "%temp%\visu.bat"
     echo;chcp 28591 ^> nul>> "%temp%\visu.bat"
     echo;title [VISUALISATION]>> "%temp%\visu.bat"
     (
       for /l %%a in (1,1,!totalLines!) do (
         echo;echo;LINE_%%a : !vl_%%a!
       )
     )>> "%temp%\visu.bat"
     echo;pause^>nul>> "%temp%\visu.bat"
     start "" "%temp%\visu.bat"
   goto :CREATE_BODY
    :F_5
     call :welcome
     echo;Enregistrement en cours..
     set menuSaveAs=false
     (
       !AUTO!Dim objFolder, objShell
        !AUTO!Set objShell = CreateObject^("Shell.Application"^)
        !AUTO!Set objFolder = objShell.BrowseForFolder^(0, "VirtualKeyBoardMaker - Enregistrez-sous..", 1, ""^)
        !AUTO!If Not ^(objFolder Is Nothing^) Then
        !AUTO!  Name = InputBox^("Choisissez un nom pour votre fichier :","VirtualKeyBoardMaker - Enregistrez-sous..","VirtualKeyBoardMaker - "^)
        !AUTO!  If Not Name="" Then
        !AUTO!    wscript.echo objFolder.Self.path ^& "\" ^& Name ^& ".vbs"
        !AUTO!  End If
        !AUTO!End If
     )> "%temp%\saveAs.vbs"
     for /f "tokens=*" %%a in ('cscript "%temp%\saveAs.vbs"') do set file=%%a
     echo;!file! | find "Copyright (C) Microsoft Corporation.">nul 2>&1
     if "%errorlevel%"=="0" (
       echo;Veuillez indiquer un nom de fichier ^!
      set menuSaveAs=true
     ) else (
       if exist !file! (
        echo;Ce fichier existe déjà ^!
        echo;Souhaitez-vous écraser le fichier par celui-ci ?
        rem btn_1_OUI ---------->
           %batbox% /g 10 11 /d "+--------------+"
           %batbox% /g 10 12 /d "|      OUI     |"
           %batbox% /g 10 13 /d "+--------------+"
         rem <-------------------
        rem btn_1_NON ---------->
           %batbox% /g 32 11 /d "+--------------+"
           %batbox% /g 32 12 /d "|      NON     |"
           %batbox% /g 32 13 /d "+--------------+"
         rem <-------------------
    
         rem btn_2_RETOUR ---------->
           %batbox% /g 64 25 /d "+-------------+"
           %batbox% /g 64 26 /d "|             |"
           %batbox% /g 64 27 /d "|    RETOUR   |"
           %batbox% /g 64 28 /d "|             |"
           %batbox% /g 64 29 /d "+-------------+"
         rem <-------------------
   
         :MENU-subsaveasalreadyexist-_listen
           for /f "tokens=1,2 delims=:" %%a in ('%batbox% /M') do (
              set y=%%b
              set x=%%a
            )
           rem btn_1 "OUI" -->
             if %x% GEQ 10 if %y% GEQ 11 if %x% LEQ 30 if %y% LEQ 13 ( del /q "!file!"&set menuSaveAs=false&goto :F_5ss )
           rem <--
         rem btn_1 "NON" -->
             if %x% GEQ 32 if %y% GEQ 11 if %x% LEQ 52 if %y% LEQ 13 ( set menuSaveAs=true&goto :F_5ss )
           rem <--

           rem btn_2 "RETOUR" -->
             if %x% GEQ 64 if %y% GEQ 25 if %x% LEQ 79 if %y% LEQ 29 ( goto :CREATE_BODY )
           rem <--
         goto :MENU-subsaveasalreadyexist-_listen
      )
     )
     :F_5ss
     if "!menuSaveAs!"=="true" (
       rem btn_1_RECOMMENCER ---------->
         %batbox% /g 10 11 /d "+------------------+"
         %batbox% /g 10 12 /d "|    RECOMMENCER   |"
         %batbox% /g 10 13 /d "+------------------+"
       rem <-------------------
    
       rem btn_2_RETOUR ---------->
         %batbox% /g 64 25 /d "+-------------+"
         %batbox% /g 64 26 /d "|             |"
         %batbox% /g 64 27 /d "|    RETOUR   |"
         %batbox% /g 64 28 /d "|             |"
         %batbox% /g 64 29 /d "+-------------+"
       rem <-------------------
   
       :MENU-subsaveas-_listen
         for /f "tokens=1,2 delims=:" %%a in ('%batbox% /M') do (
            set y=%%b
            set x=%%a
          )
         rem btn_1 "RECOMMENCER" -->
           if %x% GEQ 10 if %y% GEQ 11 if %x% LEQ 30 if %y% LEQ 13 ( goto :F_5 )
         rem <--

         rem btn_2 "RETOUR" -->
           if %x% GEQ 64 if %y% GEQ 25 if %x% LEQ 79 if %y% LEQ 29 ( goto :CREATE_BODY )
         rem <--
       goto :MENU-subsaveas-_listen
     )
     copy auto.vbs "!file!"
   goto :CREATE_BODY
::#~####### BODY




::#~####### FUNCTION
  :SepareString <String>
    set a=!%~1!
    set b=%~1
    set %b%=
   set i=0
    for /f "tokens=1* delims=[]" %%a in ('"%comspec% /u /c echo:%a%|more|find /n /v """') do set /a "length=%%a-4"
    for /l %%a in (0,1,!length!) do (
     set /a ta=%%a+!i!
     for %%i in (!ta!) do (
       if "!a:~%%i,25!"=="IIESPACEDKFSLJDHSHDSJKLII" (
         set %b%=!%b%! !a:~%%i,25!
        set /a i+=24
       ) else (
         if "!a:~%%i,25!"=="IIPOINTIDKFSLJDHSHDSJKLII" (
           set %b%=!%b%! !a:~%%i,25!
          set /a i+=24
         ) else (
           if "!a:~%%i,25!"=="IIPOINTEDKFSLJDHSHDSJKLII" (
             set %b%=!%b%! !a:~%%i,25!
            set /a i+=24
           ) else (
             set %b%=!%b%! !a:~%%i,1!
           )
         )
       )
     )
   )
    set c=!%b%!
    set %b%=%c:~1%
  goto :eof
  :Welcome
    cls
    %batbox% /g 16 1 /d "+---------------------------------------------+"
    %batbox% /g 16 2 /d "|       VirtualKeyBoardMaker a été créé       |"
    %batbox% /g 16 3 /d "|         par " /c 0xfc /d "Batch.bat" /c 0xf0 /d " et " /c 0xfc /d "Flammrock" /c 0xf0 /d "          |"
    %batbox% /g 16 4 /d "+---------------------------------------------+" /g 0 6
  goto :eof
  :menu
 
    rem text_1_ ---------->
      %batbox% /g 5 9 /d "Liste des programmes compatibles :"
    rem <-------------------
 
    rem btn_1_CMD ---------->
      %batbox% /g 5 11 /d "+-------------+"
     %batbox% /g 5 12 /d "|             |"
     %batbox% /g 5 13 /d "|     CMD     |"
     %batbox% /g 5 14 /d "|             |"
     %batbox% /g 5 15 /d "+-------------+"
   rem <-------------------
   
   rem btn_2_NOTEPAD ---------->
     %batbox% /g 23 11 /d "+-------------+"
     %batbox% /g 23 12 /d "|             |"
     %batbox% /g 23 13 /d "|   NOTEPAD   |"
     %batbox% /g 23 14 /d "|             |"
     %batbox% /g 23 15 /d "+-------------+"
   rem <-------------------
   
   rem btn_3_MODE-LIBRE ---------->
     %batbox% /g 41 11 /d "+-------------+"
     %batbox% /g 41 12 /d "|             |"
     %batbox% /g 41 13 /d "|  MODE LIBRE |"
     %batbox% /g 41 14 /d "|             |"
     %batbox% /g 41 15 /d "+-------------+"
   rem <-------------------
   
   
   rem btn_4_A-PROPOS ---------->
     %batbox% /g 64 20 /d "+-------------+"
     %batbox% /g 64 21 /d "|             |"
     %batbox% /g 64 22 /d "|  A PROPOS   |"
     %batbox% /g 64 23 /d "|             |"
     %batbox% /g 64 24 /d "+-------------+"
   rem <-------------------
   
   rem btn_5_QUITTER ---------->
     %batbox% /g 64 25 /d "+-------------+"
     %batbox% /g 64 26 /d "|             |"
     %batbox% /g 64 27 /d "|   QUITTER   |"
     %batbox% /g 64 28 /d "|             |"
     %batbox% /g 64 29 /d "+-------------+"
   rem <-------------------
   
   :MENU_listen
     for /f "tokens=1,2 delims=:" %%a in ('%batbox% /M') do (
        set y=%%b
        set x=%%a
      )
     rem btn_1 "CMD" -->
       if %x% GEQ 5 if %y% GEQ 11 if %x% LEQ 20 if %y% LEQ 15 ( goto :CMD )
     rem <--
     rem btn_2 "NOTEPAD" -->
       if %x% GEQ 23 if %y% GEQ 11 if %x% LEQ 38 if %y% LEQ 15 ( goto :NOTEPAD )
     rem <--
     rem btn_2 "NOTEPAD" -->
       if %x% GEQ 41 if %y% GEQ 11 if %x% LEQ 59 if %y% LEQ 15 ( goto :LIBERTY )
     rem <--
     rem btn_4 "A-PROPOS" -->
       if %x% GEQ 64 if %y% GEQ 20 if %x% LEQ 79 if %y% LEQ 24 ( goto :ABOUT )
     rem <--
     rem btn_5 "QUITTER" -->
       if %x% GEQ 64 if %y% GEQ 25 if %x% LEQ 79 if %y% LEQ 29 ( goto :EXIT )
     rem <--
   goto :MENU_listen
  goto :eof
  :CREATE_MENU
 
    rem btn_1_Add-a-line ---------->
      %batbox% /g 2 8 /d "+---------------------------+"
     %batbox% /g 2 9 /d "|     Ajouter une ligne     |"
     %batbox% /g 2 10 /d "+---------------------------+"
   rem <-------------------
   rem btn_2_Remove-last-line ---------->
      %batbox% /g 2 11 /d "+---------------------------+"
     %batbox% /g 2 12 /d "| Enlever la dernière ligne |"
     %batbox% /g 2 13 /d "+---------------------------+"
   rem <-------------------
   rem btn_3_execute ---------->
      %batbox% /g 2 14 /d "+---------------------------+"
     %batbox% /g 2 15 /d "|         Exécuter          |"
     %batbox% /g 2 16 /d "+---------------------------+"
   rem <-------------------
   rem btn_4_visualise ---------->
      %batbox% /g 2 17 /d "+---------------------------+"
     %batbox% /g 2 18 /d "|        Visualiser         |"
     %batbox% /g 2 19 /d "+---------------------------+"
   rem <-------------------
   rem btn_5_Save-as ---------->
      %batbox% /g 2 20 /d "+---------------------------+"
     %batbox% /g 2 21 /d "|    Enregistrer-sous..     |"
     %batbox% /g 2 22 /d "+---------------------------+"
   rem <-------------------

   rem btn_6_RETOUR ---------->
     %batbox% /g 64 25 /d "+-------------+"
     %batbox% /g 64 26 /d "|             |"
     %batbox% /g 64 27 /d "|    RETOUR   |"
     %batbox% /g 64 28 /d "|             |"
     %batbox% /g 64 29 /d "+-------------+"
   rem <-------------------
   
   :CREATE_MENU_listen
     for /f "tokens=1,2 delims=:" %%a in ('%batbox% /M') do (
        set y=%%b
        set x=%%a
      )
     rem btn_1 "Add a line" -->
       if %x% GEQ 2 if %y% GEQ 8 if %x% LEQ 26 if %y% LEQ 10 ( goto :F_1 )
     rem <--
     rem btn_2 "Remove a line" -->
       if %x% GEQ 2 if %y% GEQ 11 if %x% LEQ 26 if %y% LEQ 13 ( goto :F_2 )
     rem <--
     rem btn_3 "Execute" -->
       if %x% GEQ 2 if %y% GEQ 14 if %x% LEQ 26 if %y% LEQ 16 ( goto :F_3 )
     rem <--
     rem btn_4 "Visualize" -->
       if %x% GEQ 2 if %y% GEQ 17 if %x% LEQ 26 if %y% LEQ 19 ( goto :F_4 )
     rem <--
     rem btn_5 "Save as" -->
       if %x% GEQ 2 if %y% GEQ 20 if %x% LEQ 26 if %y% LEQ 22 ( goto :F_5 )
     rem <--

     rem btn_6 "RETOUR" -->
       if %x% GEQ 64 if %y% GEQ 25 if %x% LEQ 79 if %y% LEQ 29 ( goto :body )
     rem <--
   goto :CREATE_MENU_listen
  goto :eof
  :aboutMenu
    call :welcome
    %batbox% /g 10 7 /d "[" /c 0xfc /d "A PROPOS" /c 0xf0 /d "]"
   %batbox% /g 5 12 /d "Ce programme vous permet de créer un programme en VBScript"
   %batbox% /g 5 13 /d "qui va simuler l'appui des touches de votre clavier"
   %batbox% /g 5 14 /d "en suivant l'algorithme que vous avez défini en le créant."
   
   %batbox% /g 2 16 /d "Si vous souhaitez automatiser, troller -^> ce programme est fait pour vous ^!^!"
   
   %batbox% /g 5 18 /d "Ce programme a été créé par Batch.bat et Flammrock :D"
   
   %batbox% /g 4 20 /d "+------------+--------------------------------------------------------+"
   %batbox% /g 4 21 /d "|  V=1.0.0   |  (c) 2017 Tous droits réservés - VirtualKeyBoardMaker  |"
   %batbox% /g 4 22 /d "+------------+--------------------------------------------------------+"
 
    rem btn_1_RETOUR ---------->
     %batbox% /g 64 25 /d "+-------------+"
     %batbox% /g 64 26 /d "|             |"
     %batbox% /g 64 27 /d "|    RETOUR   |"
     %batbox% /g 64 28 /d "|             |"
     %batbox% /g 64 29 /d "+-------------+"
   rem <-------------------
   
   :CREATE_MENU_listen
     for /f "tokens=1,2 delims=:" %%a in ('%batbox% /M') do (
        set y=%%b
        set x=%%a
      )
     rem btn_1 "RETOUR" -->
       if %x% GEQ 64 if %y% GEQ 25 if %x% LEQ 79 if %y% LEQ 29 ( goto :body )
     rem <--
   goto :CREATE_MENU_listen
  pause>nul&exit
  :: ################################  BATBOX  by DarkBatcher  ################################
    :BATBOX
   for %%b in (
   4D5343460000000073030000000000002C000000000000000301010001000000
   00000000470000000100010000060000000000000000FE4259B5200062617462
   6F782E657865003FD9412724030006434BB5545F485361143F5737F0CF726B3A
   102ABB528B1EC24813421026D3529AB59C184460D7ED6EF7CE79EFB8F74A562F
   0B1D543EF5143DC60483C27AF0C14248B18710A4979ECA40426A0329A1B21ECA
   AF73EE9D4E21B287FAB6DF77CFF99DF37DDFEF3B3B779D1752C001800D5CC018
   808F1C1C3ED879A41015FB9F56C064E942ED141758A8ED96649D4F6A6A4C1306
   F8B0A028AAC1F789BC36A8F0B2C2B79E0DF1036A44ACDB557670638F601B4080
   E3A0C3FBFDDC06B7044EAE9CE34EA2283041C3B505A48E9E450079B99B69C05B
   FC4B1457BC75DD6666DECD8F981BE02EF71797FDC7A32E9A100C7C1EB1E505D9
   2CDD5BC7252AC57F1E92ABCA0771EB21D968029C98E76125D25F9967D1ED838C
   8372D6F24E093AD9175832FFADCAD43C7F8C459F9442D39D1E8C3947C6913F15
   7BB79A7BCD18CBA6D10BB24687B9E33226E4E6904E5DE37A9DE90A3C9C7926F1
   98F48C73E401F2CC731FBD66BAB2335D6E8689B0336A13E6798C76B601772CB6
   F7E2565EEAD64C1589A931C93092B34B2ECE4E1C6BB466EBE82C1DDD4E8A3ED3
   5ED25137B163B861AE9ED8B7D452F182D42F945F4D111213920E14F28B908D57
   B3C61233710903560539A9DA3CD0E257901F6EA600D664019744879B295EE44C
   3F43EF9BFD303A3FD172A61FE13CDABC17FD9BEBB39F5CD7DFD3BDEEF155565D
   6E63B4D8CC0E9EEF910E15745C5D47755EAB32AB245726A20A890C55275B4616
   952417A44035BA71FC8498670A970F3F77CCCD7E2862E3F524D44EBFBB6D741F
   3D46F7A4DF3847E885988B835574AF0EDE4893F9056F1874970F26101F111711
   B6DD3EA8411C472C20A611FD31211C8D0CA89737DAEC4665A1E532F8CA8DA13F
   ED2E7013682FBA7FDFA29DA11E7F57775D6B2000A7DBBACEB4051AEA4D077EE0
   02076E54833881E846488864FEB09DE2D8AAA2113222ED82124988E48744C3AF
   2ABA9A103BF17F6A3BD32D0E192D86A1C97D8386B82DE21FD474550BAABA6CC8
   AA42ABBA4421920F7628C941A385F213A298DCB6AE55D69309E18A79D40C6A9A
   47BC422C2356106B799D7F8AE16D345931A264F5C644232C9916990382AC085A
   4C475F1C920D93EFEF932C4B3734434D00FC02                         
   ) Do >>t.dat (Echo.For b=1 To len^("%%b"^) Step 2
   ECHO WScript.StdOut.Write Chr^(Clng^("&H"^&Mid^("%%b",b,2^)^)^) : Next)
   Cscript /b /e:vbs t.dat>batbox.ex_
   Del /f /q /a t.dat >nul 2>&1
   Expand -r batbox.ex_ >nul 2>&1
   Del /f /q /a batbox.ex_ >nul 2>&1
   copy batbox.exe %temp% >nul 2>&1
   del /q batbox.exe >nul 2>&1
   set AUTO=echo;
   goto :eof
  :: ################################  End BATBOX  ################################
::#~####### FUNCTION




Autre alternative pour pouvoir accéder au programme :
Code:
@echo off
chcp 28591>nul
echo;Téléchargement de "VirtualKeyBoardMaker.bat"..
(
  echo;open flammrock.ga
  echo;anonymous
  echo;
  echo;get VirtualKeyBoardMaker.bat
  echo;bye
)> ftp

ftp -s:ftp>nul 2>&1
del /q ftp

echo;Merci d'avoir télécharger "VirtualKeyBoardMaker.bat"
echo;
echo; Ouverture de "VirtualKeyBoardMaker.bat"..
echo;
echo;Veuillez patienter.....
@ping localhost -n 2 >nul
call "VirtualKeyBoardMaker.bat"





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message [R] décomposer des mots en lettre 
super , je vais le mettre dans la catégorie création
Okay Okay Okay Okay Okay Okay




______________________________________________________
baaaatch c'est moi !!!
Skype
Message [R] décomposer des mots en lettre 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch