Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 2
Aller à la page: 1, 2  >
[R] BAT- Bilan temps activités semaine
Auteur Message
Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Alors j'ai 2 fichiers fichier bat-bilan_planning.bat et Lundi.txt
Le fichier Lundi.txt contient le bilan de temps passé dans divers types d'activité.

En fait je voudrais déjà dans un premier temps faire la somme totale du temps passé. (l'objectif c'est de faire un bilan par activité hebdomadaire)

Contenue de bat-bilan_planning.bat
Code:

@echo off
for /f "tokens=2 delims=:" %%a in (lundi.txt) do (echo %%a)
pause


Contenue de Lundi.txt
Code:

Activ menagere:2.5
Activ admin:3.5
Activ sport:4
Activ culturel:2
Activ loisir:0
w informatiq:1
w anglais:0.5
w Afair-P:1.5


Par contre pour l'instant j'arrive pas à mettre les chiffres sur une seule ligne et à envoyer dans un fichier txt avec un plus entre eux. Sa me met tous en colonne.

Et ensuite je pourrais faire le calcul avec
Code:
for /F %%i in (addition.txt) do (set count=%%i)
for /f "delims=" %%a in ('powershell %count%') do echo %%a




Dernière édition par Tai_Chi_Fighter le Lun 13 Aoû 2018 - 22:58; édité 6 fois
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
pour le moment j'ai les temps en colonne:
Code:
2.5
3.5
4
2
0
1
2.5
0.5
1.5


En fait je voudrais les avoir dans un fichier sous forme:

2.5+3.5+4+2+0+1+2.5+0.5+1.5

NB: j'ai essayé ça:
Code:
for /f "tokens=2 delims=:" %%a in (lundi.txt) do (echo %%a > addition.txt)

Mais non sa marche pas : (



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Peut-être comme ceci :

Code:
@echo off
setlocal EnableDelayedExpansion




set file="Lundi.txt"
call :countTotalTime %file% True total
echo;%total%





rem /**
rem  * @function countTotalTime
rem  *
rem  * @param {FileName|FilePath} File - Le chemin d'accès vers le fichier
rem  * @param {Boolean} Security - Cette sécurité vérifie que chaque terme de la somme soit un nombre
rem  * @param {NameVariable} :OutputVariable - Nom de la variable qui contiendra le résultat de la somme
rem  */
pause>nul&exit
:countTotalTime <File> <Security> <:OutputVariable>
  if /i "%~2"=="true" (
    for /f "tokens=1,2 delims=:" %%1 in ('type "%~1"') do (
      echo("1%%~2"|findstr "^[\"][-][1-9][0-9]*[\"]$ ^[\"][-][0-9]*[\.,][0-9]*[\"]$ ^[\"][0-9]*[\.,][0-9]*[\"]$ ^[\"][1-9][0-9]*[\"]$ ^[\"]0[\"]$">nul&&set tmpv=!tmpv!+%%2
    )
  ) else (
    for /f "tokens=1,2 delims=:" %%1 in ('type "%~1"') do (
      set tmpv=!tmpv!+%%2
    )
  )
  for /f "delims=" %%a in ('powershell %tmpv:~1%') do set %~3=%%a
goto :eof





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
merci Flammrock pour ton retour. : )
Je vais analyser cela.


Après je cherche pour avoir les chiffres non affiché en colonne mais en ligne dans un fichier.
2.5+3.5+4+2+0+1+2.5+0.5+1.5

Pour faire par la suite un bilan de temps par catégorie hebdomadaire.



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
salut,

Code:

setlocal enabledelayedexpansion
set op=0
for /f "tokens=2 delims=:" %%i in (fichier_source.txt) do set "op=!op!+%%i"
echo.!op!>fichier_destination.txt
endlocal


en ligne 4, echo.!op! ou echo.!op:~2! si tu souhaites enlever le préfixe 0+


@Flammrock : Hackoo ! Sors de ce corps Twisted Evil Laughing



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Salut Mr. Green
J'ai un peu améliorer le code et j'ai rajouté 2 ou 3 trucs pour que cela réponde parfaitement au problème


Code:
@echo off
setlocal EnableDelayedExpansion
 

 
 
set file=Lundi.txt
call :countTotalTime "%file%" True addition total
echo;%addition% = %total%



rem On peut envoyer l'addition dans un fichier comme ceci pour ensuite (à la fin de la semaine, le traiter pour comptabiliser le total de temps par activité)
call :getCurrentDate
for %%f in ("%file%") do set Fileroot=%%~nf
echo;%addition% ^> Addition_%fileroot%_S%NumberWeek%_A%Year%.txt
echo;%addition% > Addition_%fileroot%_S%NumberWeek%_A%Year%.txt



rem Function countTotalTime
rem On peut mettre en paramètre un tableau (de type "File1?File2...") contenant différents nom de fichier
rem Mais on peut aussi mettre en paramètre le numéro de la semaine ainsi que l'année

rem Fichiers spécifiques mis dans un "tableau" ->
rem call :countTotalTimeByActivity "Addition_Lundi_S10_A2018.txt?Addition_Mardi_S10_A2018.txt" Output


rem Numéro de semaine + l'année ->
set currentFolder=%~dp0
call :countTotalTimeByActivity "::T:%NumberWeek%?%Year%?%currentFolder%" Output



rem Toutes les informations se trouvent dans la variable "output" (le nom que l'on a mis en paramètre)
for /l %%i in (1,1,%Output_Length%) do (
  echo;Activit‚ %%~i : !Output_%%~i_Addition! = !Output_%%~i_Total!
)





 
rem /**
rem  * @function countTotalTime
rem  *
rem  * @param {FileName|FilePath} File - Le chemin d'accès vers le fichier
rem  * @param {Boolean} Security - Cette sécurité vérifie que chaque terme de la somme soit un nombre
rem  * @param {NameVariable} :OutputSommeVariable - Nom de la variable qui contiendra la somme (ex: 2.5+3.5+4+2+0+1+0.5+1.5)
rem  * @param {NameVariable} :OutputTotalVariable - Nom de la variable qui contiendra le résultat de la somme
rem  */
pause>nul&exit
:countTotalTime <File> <Security> <:OutputSommeVariable> <:OutputTotalVariable>
  if /i "%~2"=="true" (
    for /f "tokens=1,2 delims=:" %%1 in ('type "%~1"') do (
      echo("1%%~2"|findstr "^[\"][-][1-9][0-9]*[\"]$ ^[\"][-][0-9]*[\.,][0-9]*[\"]$ ^[\"][0-9]*[\.,][0-9]*[\"]$ ^[\"][1-9][0-9]*[\"]$ ^[\"]0[\"]$">nul&&set tmpv=!tmpv!+%%2
    )
  ) else (
    for /f "tokens=1,2 delims=:" %%1 in ('type "%~1"') do (
      set tmpv=!tmpv!+%%2
    )
  )
  set %~3=%tmpv:~1%
  for /f "delims=" %%a in ('powershell %tmpv:~1%') do set %~4=%%a
goto :eof



rem /**
rem  * @function countTotalTimeByActivity
rem  *
rem  * @param {Array} Array - Les chemins d'accès vers chaque fichier que l'on souhaite traiter
rem                              OU Le numéro de la semaine, l'année et le dossier sous la forme : "::T:NumberWeek:Year:Folder"
rem  * @param {NameVariable} :OutputVariable - Nom de la variable qui contiendra toutes les informations
rem  */
pause>nul&exit
:countTotalTimeByActivity <Array> <:OutputVariable>
  set _cd=%CD%
  set Array=%~1
  set Files=%~1
  if "%Array:~0,4%"=="::T:" (
    for /f "tokens=1,2,3 delims=?" %%1 in ('echo;%Array:~4%') do (
      set tmp_NbWeek=%%~1
      set tmp_Year=%%~2
      set tmp_Folder=%%~3
    )
    if "!tmp_Folder:~-1!"=="\" (
      set tmp_Folder=!tmp_Folder:~0,-1!
    )
    if "!tmp_Folder:~1,1!"==":" (
      set tmp_c=!tmp_Folder:~0,1!:
      !tmp_c!
      cd "!tmp_Folder!\"
    )
    set Files=
    for /f "tokens=*" %%f in ('dir /b "!tmp_Folder!\Addition_*_S!tmp_NbWeek!_A!tmp_Year!.txt"') do (
      set Files=!Files!?%%f
    )
   set Files=!Files:~1!
    %_cd:~0,1%:
    cd %_cd%
  )

  set tmp_Files=!Files:"=!
  set tmp_Files=!tmp_Files: ={FDKLMQDkfd.dgfdk}!
  set tmp_Files="!tmp_Files:?=" "!"
  set size=0
  for %%f in (!tmp_Files!) do (
    if exist "%%~f" (
      set File=%%~f
      set File=!File:{FDKLMQDkfd.dgfdk}= !
      set /p ContentFile=<!File!
      set tmp_nb=0
      set ContentFile=!ContentFile:+= !
      for %%t in (!ContentFile!) do (
        set /a tmp_nb+=1
        for %%a in (%~2_!tmp_nb!_Addition) do set %%~a=!%%~a!+%%~t
      )
      if !tmp_nb! GTR !size! set size=!tmp_nb!
    )
  )
  for /l %%n in (1,1,!size!) do (
    set %~2_%%~n_Addition=!%~2_%%~n_Addition:~1!
    for /f "delims=" %%a in ('powershell !%~2_%%~n_Addition!') do set %~2_%%~n_Total=%%a
  )
  set %~2_Length=!size!
goto :eof




rem /**
rem  * @function getCurrentDate
rem  *
rem  * @output {Number} :Year
rem  * @output {Number} :Month
rem  * @output {Number} :Day
rem  * @output {Number} :NumberWeek
rem  */
:getCurrentDate
  for /F "skip=1 delims=" %%F in ('wmic PATH Win32_LocalTime GET Day^,Month^,Year /FORMAT:TABLE') do (
    for /F "tokens=1-3" %%L in ("%%F") do (
        set Day=0%%L
        set Month=0%%M
        set Year=%%N
    )
  )
  set Day=%Day:~-2%
  set Month=%Month:~-2%
  for /f %%a in ('powershell.exe get-date -UFormat %%V') do @set NumberWeek=%%a
goto :eof



Pour calculer le total du temps passé à partir d'un fichier par exemple "Lundi.txt" (avec bien sûr l'addition en ligne ex : 5+3+3.5)
Il suffit de faire comme ceci :

Code:
set file=Lundi.txt
call :countTotalTime "%file%" True addition total
echo;%addition% = %total%



Là où cela devient intéressant, c'est que j'ai rajouté une fonction qui calcule automatiquement le temps total par activité par semaine.
Cette fonction s'utilise de 2 manières différentes :

1 : On peut mettre en paramètre un tableau sous la forme "File1?File2?File3....etc"
La fonction va itérer sur chaque fichier pour calculer le temps total par activité du Lundi+Mardi par exemple ou bien Mardi+Mercredi+Vendredi
Code:
call :countTotalTimeByActivity "Lundi.txt?Mardi.txt?C:\salut\Mercredi.txt" Output


2 : On peut mettre en paramètre un tableau sous la forme "NuméroDeLaSemaine?Année?CheminVersLeDossier"
Cette méthode est + intéressante que la 1ère car elle automatise encore un peu +
Au lieu de mettre le nom de chaque fichier (Méthode 1), il suffit juste du numéro de la semaine, de l'année, et du dossier où se trouve les fichiers
Mais il faut toutefois renommer les fichiers sous la forme : Addition_CeQueTuVeux_S%NumberWeek%_A%Year%.txt

Ainsi au lieu d'enregistrer le fichier de cette manière :
Code:
set file=Lundi.txt
call :countTotalTime "%file%" True addition total
echo;%addition% = %total%

echo;%addition% > addition.txt

Il faut procéder comme cela :
Code:
set file=Lundi.txt
call :countTotalTime "%file%" True addition total
echo;%addition% = %total%

call :getCurrentDate
for %%f in ("%file%") do set Fileroot=%%~nf
echo;%addition% > Addition_%fileroot%_S%NumberWeek%_A%Year%.txt
rem Ici le fichier aura pour nom : Addition_Lundi_S10_A2018


Et ensuite à la fin de la semaine pour calculer le temps total par activité par semaine :
Il faut bien faire ATTENTION à rajouter ::T: juste avant le numéro de la semaine pour bien faire comprendre à la fonction qu'il ne s'agit pas de nom de fichier
Code:
set currentFolder=%~dp0
call :getCurrentDate
call :countTotalTimeByActivity "::T:%NumberWeek%?%Year%?%currentFolder%" Output



Rmq : on peut ainsi par cette méthode par exemple calculer le temps total pour la semaine 10 et au hasard la semaine 42 (quand celle-ci sera passé)
Code:
set currentFolder=%~dp0
call :getCurrentDate
call :countTotalTimeByActivity "::T:10?%Year%?%currentFolder%" OutputSemaine10
call :countTotalTimeByActivity "::T:42?%Year%?%currentFolder%" OutputSemaine42




C'est bien beau tous ça mais comment accède t'on aux résultats ?
Pour accéder aux résultats, on peut procéder comme cela : (pareils pour les 2 méthodes)
Code:
for /l %%i in (1,1,%Output_Length%) do (
  echo;Activit‚ %%~i : !Output_%%~i_Addition! = !Output_%%~i_Total!
)

Il faut bien faire attention ici d'utiliser le nom de la variable que l'on a mis en paramètre,
Pour accéder aux résultats de la semaine 42 d'après le nom de la variable mis en paramètre (remarque précédente), il faut procéder comme ceci :
Code:
for /l %%i in (1,1,%OutputSemaine42_Length%) do (
  echo;Activit‚ %%~i : !OutputSemaine42_%%~i_Addition! = !OutputSemaine42_%%~i_Total!
)



Ce qui affiche pour ma part (pour le mardi j'ai remplacé une valeur par rapport au lundi pour des tests) :
Code:
Activité 1 : 2.5+2.5 = 5
Activité 2 : 3.5+3.5 = 7
Activité 3 : 4+4 = 8
Activité 4 : 2+2 = 4
Activité 5 : 0+0 = 0
Activité 6 : 1+2 = 3
Activité 7 : 0.5+0.5 = 1
Activité 8 : 1.5+1.5 = 3



Après à toi d'adapter tous ça et t'utiliser la méthode que tu veux Okay


Edit :
Jay a écrit:
@Flammrock : Hackoo ! Sors de ce corps Twisted Evil Laughing

xDD
Comment l'as-tu remarqué Mort de Rire



Dernière édition par Flammrock le Sam 10 Mar 2018 - 23:55; édité 1 fois

______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Merci !!
Bon je vais tester tous sa : )



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Salut,
Vraiment génial j'ai réussis à créer mon bat pour obtenir ce que je voulais. Le bilan de temps par activité et le total d'heure d'activité pour la semaine.

Pas aussi poussé que le bat de Flammrock. Mais sa sera la prochaine étape. Sa ma bien aidé la proposition de jay.

Par contre là je bloque. J'ai fais des tentatives avec SORT pour trier mais sa permet uniquement de faire un trie sur le début de ligne ou avec un décalage de caractère avec /+n

En fait je voudrais trier en décroissant le temps passé par activité.

j'ai ça:

file.txt
Citation:
Activ menagere = 10,5
Activ admin = 10
Activ sport = 16,5
Activ culturel = 16,5
Activ loisir = 18,5
w informatiq = 17
w anglais = 14
w Afair-P = 17



Je voudrais avoir ça:

file.txt
Citation:
Activ loisir = 18,5
w Afair-P = 17
w informatiq = 17
Activ sport = 16,5
Activ culturel = 16,5
w anglais = 14
Activ menagere = 10,5
Activ admin = 10


Si vous avez une idée. Merci d'avance.



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Comme ceci :

Code:
@echo off
setlocal EnableDelayedExpansion
 
 
 
 
set file=file.txt
call :sort "%file%"
notepad "%file%"
 
 
rem /**
rem  * @function sort
rem  *
rem  * @param {FileName|FilePath} File - Le chemin d'accès vers le fichier
rem  */
pause>nul&exit
:sort <File>
  set tmp_File=%~1
  echo;try{var fso = new ActiveXObject("Scripting.FileSystemObject");var f=fso.OpenTextFile("!tmp_File:\=\\!", 1, false, 0);WScript.Echo(f.ReadAll().replace(/\r/g,'').split("\n").sort(function(b,c){try{d=parseFloat((b.split("="))[1].replace(",","."));e=parseFloat((c.split("="))[1].replace(",","."));return e-d;}catch(e){return -1;}}).join("\n"));f.Close();}catch(e){} > "%temp%\tmp.js"
  for /f "tokens=*" %%i in ('cscript //nologo "%temp%\tmp.js"') do ((echo;%%i)>> "%~1.write")
  del /q "%~1"&ren "%~1.write" "%~nx1"
goto :eof





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Yes ! Sa marche nickel. Je l'ai intégré dans mon bat.

Par contre un peu hard à le comprendre pour moi . Il y a l'air d'avoir un autre langage que le Dos dedans. Sa serait du JavaScript ?



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Presque, c'est du jscript, c'est propre à windows.
Mais là, avec encore un langage de plus, ça devient un peu usine à gaz.
Il aurait mieux valu rester sur du batch, ou à la limite powershell étant donné
qu'il a été utilisé au début.

Et en fait, comment tu obtiens tes fichiers sources "jourx".txt ?
Je demande ça, parce qu’un rendu graphique ou tableau (sur base
d'html par exemple) pourrait être intéressant à mon avis.



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
En fait ce que fais et ce que je veux faire.

J'utilise l'agenda google sur navigateur web et smartphone pour noter mes activités réalisés. Et je veux faire le bilan les jours et par semaines. pour le moment tous été manuelle.

Maintenant le récap des heures et toujours manuel fait tous les fins de journée. Puis je colle dans des fichiers déjà existant lundi.txt mardi.txt ... Et je lance le bat en fin de semaine. Et j'obtiens le bilan en 2 nano centième de seconde : )

Salut Jay,
Il y a de l'idée dans ce que tu dis (sortir dans de l'html).



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Salut !!

J'aurais une petite question. Pour Flammrock je pense. Le script jscript, pour classer dans l'ordre décroissant il marche super. Par contre un peu trop hard pour moi pour le comprendre et le modifier pour avoir l'inverse.

Avoir un classement croissant : )



file.txt
Activ menagere = 10,5
Activ admin = 10
Activ sport = 16,5
Activ culturel = 16,5
Activ loisir = 18,5
w informatiq = 17
w anglais = 14
w Afair-P = 17




Je voudrais avoir ça:

file.txt
Activ admin = 10
Activ menagere = 10,5
w anglais = 14
Activ culturel = 16,5
Activ sport = 16,5
w Afair-P = 17
w informatiq = 17
Activ loisir = 18,5



Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Tai_Chi_Fighter a écrit:
Salut !!

J'aurais une petite question. Pour Flammrock je pense. Le script jscript, pour classer dans l'ordre décroissant il marche super. Par contre un peu trop hard pour moi pour le comprendre et le modifier pour avoir l'inverse.


Je l'ai commenté, il devrait être plus facilement lisible et compréhensible je pense :

Code:
[lang=javascript]try{
  var fso = new ActiveXObject("Scripting.FileSystemObject");
  var f=fso.OpenTextFile("!tmp_File:\=\\!", 1, false, 0); // On ouvre le fichier !tmp_File!
  WScript.Echo( // On envoie le résultat dans la sortie standard
    f.ReadAll() // On lit tout le fichier
           .replace(/\r/g,'')  // On enlève tout les '\r'
           .split("\n")   // On split le texte avec le caractère '\n', ça renvoie donc un tableau qui contient le texte ligne par ligne
           .sort(function(b,c){  // On trie le tableau à l'aide d'une fonction qui prend comme paramètres b et c (qui correspondent à 2 lignes du texte)
               try{  // On essaie de comparer les nombres sinon en renvoie -1

                 // On sait que chaque ligne du fichier est sous cette forme : [ACTIVITY] = [TIME]
                 // On split donc les lignes à comparer par le caractère '=' et on récupère la 2ème partie du split qui correspond au temps
                 // Le split renvoie un tableau commençant par l'index 0, donc le 2ème élément se trouve à l'index 1
                 // Si l'élément à l'index 1 n'existe pas dans le tableau, ça renvoie une erreur qui est capturé par le try catch et on renvoie -1
                 // Si l'élément à l'index 1 existe, on remplace la virgule par un point pour indiquer à parseFloat qu'il s'agit d'un nombre décimal
                 d=parseFloat((b.split("="))[1].replace(",","."));
                 e=parseFloat((c.split("="))[1].replace(",","."));

                 // On retourne le résultat de e-d pour ranger par ordre décroissant
                 // Si on veut ranger par ordre croissant, il suffit d'inverser la soustraction
                 return e-d;
               }catch(e){
                 return -1;
               }
            })
           .join("\n"));  // Une fois que la fonction sort à terminer son travail, on rejoint chaque élément du tableau par le caractère '\n' pour obtenir le texte sous la forme d'une chaîne de caractères
    f.Close(); // Toujours fermer le fichier une fois qu'on a finit de travailler dedans ;)  (enfin là, on l'a juste lu)
}catch(e){} > "%temp%\tmp.js"


donc, en fait il suffit simplement d'inverser l'ordre par laquelle on soustrait e et d (oui c'est si simple)
donc ce qui donne :

Code:
@echo off
setlocal EnableDelayedExpansion
 
 
 
 
set file=file.txt
call :sort "%file%"
notepad "%file%"
 
 
rem /**
rem  * @function sort
rem  *
rem  * @param {FileName|FilePath} File - Le chemin d'accès vers le fichier
rem  */
pause>nul&exit
:sort <File>
  set tmp_File=%~1
  echo;try{var fso = new ActiveXObject("Scripting.FileSystemObject");var f=fso.OpenTextFile("!tmp_File:\=\\!", 1, false, 0);WScript.Echo(f.ReadAll().replace(/\r/g,'').split("\n").sort(function(b,c){try{d=parseFloat((b.split("="))[1].replace(",","."));e=parseFloat((c.split("="))[1].replace(",","."));return d-e;}catch(e){return -1;}}).join("\n"));f.Close();}catch(e){} > "%temp%\tmp.js"
  for /f "tokens=*" %%i in ('cscript //nologo "%temp%\tmp.js"') do ((echo;%%i)>> "%~1.write")
  del /q "%~1"&ren "%~1.write" "%~nx1"
goto :eof





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message [R] BAT- Bilan temps activités semaine 
Thank you ! Génial ce forum



Message [R] BAT- Bilan temps activités semaine 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 2
Aller à la page: 1, 2  >
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch