Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
Ouvrir un dossier contenant des vidéos VLC démarrage
Auteur Message
Répondre en citant
Message Ouvrir un dossier contenant des vidéos VLC démarrage 
Bonjour,

novcie en batch, je souhaite ouvrir au démarrage de mon PC VLC et qu il lise à la suite et en boucle toutes les vidéos d'un dossier.
De plus je souhaite que tous les 15 min, il mette à jour cette liste de vidéos si le dossier a été modifié.

Merci beaucoup pour votre aide Smile

PLFP



Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message Ouvrir un dossier contenant des vidéos VLC démarrage 
salut, voici un code qui pourrait t'aider :

Les 4 premiere variable sont modifiables en fonction de ce dont tu as besoin

@+ Wink

Code:

@echo off
setlocal enabledelayedexpansion

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Repertoire ou se trouve Vlc.exe
Set "VlcPath=C:\Program Files (x86)\VideoLAN\VLC"

:: Repertoire de tes videos
set "VideoPath=C:\Videos"

:: Les extensions videos possibles
set "Vext=mp4,wmv,avi"

:: le temps d'actualisation en secondes, ici 900 donc 15 minutes
set "Actu=900"

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::


Set ListeL=Nope
:Boukle
set "ListeC="
for /f "delims=" %%$ in ('dir /b "%VideoPath%"') do set "ListeC=!ListeC!_%%$"
if not "%ListeC%"=="%ListeL%" (
   call :Npl
   if not "!ListeL!"=="Nope" taskkill /f /im "vlc.exe" > nul
   start "" "%VlcPath%\Vlc.exe"!Liste!
)
set "ListeL=%ListeC%"
echo.&echo Actualisation...
ping localhost -n %Actu% > nul
goto:Boukle

:Npl
Set "Liste="
echo --------
for /f "delims=" %%$ in ('dir /b "%VideoPath%\*.*"') do (
   for /f "delims=. tokens=2" %%A in ("%%$") do (
      set Ext=%%A
   )
   for %%# in (!Vext!) do (
      if "%%#"=="!Ext!" (
         echo - %%$
         set "Liste=!Liste! "!VideoPath!\%%$""
      )
   )
)
goto:eof


EDIT: Et pour que ton fichier bat se lance au demarrage du Pc, créé un racourci vers le fichier et place le dans C:\Users\Ton nom de Session Windows\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup




______________________________________________________
Site MagicDosYoutubeFacebookVietcong 2 OlympeVietcong 2 Alliance
Visiter le site web du posteur Skype
Message Ouvrir un dossier contenant des vidéos VLC démarrage 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch