Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
[R] Convertir un texte en tableau HTML ?
Auteur Message
Répondre en citant
Message [R] Convertir un texte en tableau HTML ? 
Salut tout le monde Smile
Je veux quelqu'un parmi vous me donne une bonne méthode pour convertir un fichier texte en tableau HTML dans ce cas particulier !
Je m'explique :
1- Supposons que j'ai déjà téléchagé ce fichier en format texte depuis cette URL : http://spys.me/proxy.txt

L'entête du tableau :

IP address:Port Country-Anonymity(Noa/Anm/Hia)-SSL_support(S)-Google_passed(+)

EDIT :
Voici ce que j'ai commencé à faire comme vbscript pour télécharger et extraire juste les lignes dont j'en ai besoin et ignorer les autres
le fichier de proxy est mis à jour toutes les heures avec 300 proxies depuis sa source bien sûr Wink
GetProxyList.vbs
Code:
'GetProxyList
Option Explicit
Dim Title,URL,Save2File,ws,fso,LogFile
Title = "Extract Proxy List from text file by Hackoo 2018"
Set ws = CreateObject("wscript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
LogFile = "NewProxyList.txt"
If fso.FileExists(LogFile) Then fso.DeleteFile LogFile
URL = "http://spys.me/proxy.txt"
Save2File = "Downloaded_proxy.txt"
Call Download(URL,Save2File)
Call WriteLog(ExtractLinesFromTextFile(Save2File,5,304),LogFile)
If fso.FileExists(LogFile) Then ws.run(LogFile)
'-------------------------------------------------------------------------------------------------------
Sub Download(URL,Save2File)
    Dim File,Line,BS,ws
    On Error Resume Next
    Set File = CreateObject("WinHttp.WinHttpRequest.5.1")
    File.Open "GET",URL, False
    File.Send()
    If err.number <> 0 then
        Line  = Line &  vbcrlf & "Error Getting File"
        Line  = Line &  vbcrlf & "Error " & err.number & "(0x" & hex(err.number) & ") " &  vbcrlf &_
        err.description
        Line  = Line &  vbcrlf & "Source " & err.source
        MsgBox Line,vbCritical,"Error getting file"
        Err.clear
        wscript.quit
    End If
    If File.Status = 200 Then ' File exists and it is ready to be downloaded
        Set BS = CreateObject("ADODB.Stream")
        Set ws = CreateObject("wscript.Shell")
        BS.type = 1
        BS.open
        BS.Write File.ResponseBody
        BS.SaveToFile Save2File, 2
    ElseIf File.Status = 404 Then
        MsgBox "File Not found : " & File.Status,vbCritical,"Error File Not Found"
    Else
        MsgBox "Unknown Error : " & File.Status,vbCritical,"Error getting file"
    End If
End Sub
'----------------------------------------------------------------------------------------------------
Public Function ExtractLinesFromTextFile(ByRef TextFile, ByRef FromLine, ByRef ToLine) '<-- Inclusive
    Const TristateUseDefault = -2 'To Open the file using the system default.
    On Error Resume Next
    If FromLine <= ToLine Then
        With CreateObject("Scripting.FileSystemObject").OpenTextFile(TextFile,1,true,TristateUseDefault)
            If Err.number <> 0 Then
                MsgBox err.description,16,err.description
                Exit Function
            Else
                Do Until .Line = FromLine Or .AtEndOfStream
                    .SkipLine
                Loop
                Do Until .Line > ToLine Or .AtEndOfStream
                    ExtractLinesFromTextFile = ExtractLinesFromTextFile & (.ReadLine & vbNewLine)
                Loop
            End If
        End With
    Else
        MsgBox "Error to Read Line in TextFile", vbCritical,"Error to Read Line in TextFile"
    End If
End Function
'----------------------------------------------------------------------------------------------------
Sub WriteLog(strText,Log)
   Dim fs,ts
   Const ForWriting = 2
   Set fs = CreateObject("Scripting.FileSystemObject")
   Set ts = fs.OpenTextFile(Log,ForWriting, True)
   ts.WriteLine strText
   ts.Close
End Sub
'----------------------------------------------------------------------------------------------------

Donc ce que je veux faire quelque chose comme ceci en tableau HTML depuis les informations extraites depuis le fichier texte : http://spys.one/en/free-proxy-list/
Merci !



Dernière édition par Hackoo le Mar 5 Juin 2018 - 21:26; édité 3 fois

______________________________________________________
Mes Contributions en Téléchargement
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message [R] Convertir un texte en tableau HTML ? 
Salut Hackoo,

sorry je ne comprends pas ta question ?




______________________________________________________


L'ignorance est un fléau qui engendre la haine et la mort
La connaissance est une arme qui surpasse toutes les autres
Partagez votre savoir, sinon il sera perdu à jamais
Répondre en citant
Message [R] Convertir un texte en tableau HTML ? 
stryk a écrit:
Salut Hackoo,
sorry je ne comprends pas ta question ?

Salut stryk Wink
J'ai édité ma question pour mieux comprendre mon but !
Merci !




______________________________________________________
Mes Contributions en Téléchargement
Répondre en citant
Message [R] Convertir un texte en tableau HTML ? 
Je peux te faire ça en Excel Laughing Laughing
Je regarde ça ce soir Wink




______________________________________________________


L'ignorance est un fléau qui engendre la haine et la mort
La connaissance est une arme qui surpasse toutes les autres
Partagez votre savoir, sinon il sera perdu à jamais
Répondre en citant
Message [R] Convertir un texte en tableau HTML ? 
Comme ça :


Code:
'GetProxyList
Option Explicit
Dim Title,URL,Save2File,ws,fso,LogFile
Title = "Extract Proxy List from text file by Hackoo 2018"
Set ws = CreateObject("wscript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
LogFile = "NewProxyList.txt"
If fso.FileExists(LogFile) Then fso.DeleteFile LogFile
URL = "http://spys.me/proxy.txt"
Save2File = "Downloaded_proxy.txt"
Call Download(URL,Save2File)
Call WriteLog(ExtractLinesFromTextFile(Save2File,5,304),LogFile)
If fso.FileExists(LogFile) Then
  'ws.run(LogFile)
  Call ConvertToHTML("ProxyList.html")
  ws.run("ProxyList.html")
End If



'-------------------------------------------------------------------------------------------------------
Sub Download(URL,Save2File)
    Dim File,Line,BS,ws
    On Error Resume Next
    Set File = CreateObject("WinHttp.WinHttpRequest.5.1")
    File.Open "GET",URL, False
    File.Send()
    If err.number <> 0 then
        Line  = Line &  vbcrlf & "Error Getting File"
        Line  = Line &  vbcrlf & "Error " & err.number & "(0x" & hex(err.number) & ") " &  vbcrlf &_
        err.description
        Line  = Line &  vbcrlf & "Source " & err.source
        MsgBox Line,vbCritical,"Error getting file"
        Err.clear
        wscript.quit
    End If
    If File.Status = 200 Then ' File exists and it is ready to be downloaded
        Set BS = CreateObject("ADODB.Stream")
        Set ws = CreateObject("wscript.Shell")
        BS.type = 1
        BS.open
        BS.Write File.ResponseBody
        BS.SaveToFile Save2File, 2
    ElseIf File.Status = 404 Then
        MsgBox "File Not found : " & File.Status,vbCritical,"Error File Not Found"
    Else
        MsgBox "Unknown Error : " & File.Status,vbCritical,"Error getting file"
    End If
End Sub
'----------------------------------------------------------------------------------------------------
Public Function ExtractLinesFromTextFile(ByRef TextFile, ByRef FromLine, ByRef ToLine) '<-- Inclusive
    Const TristateUseDefault = -2 'To Open the file using the system default.
    On Error Resume Next
    If FromLine <= ToLine Then
        With CreateObject("Scripting.FileSystemObject").OpenTextFile(TextFile,1,true,TristateUseDefault)
            If Err.number <> 0 Then
                MsgBox err.description,16,err.description
                Exit Function
            Else
                Do Until .Line = FromLine Or .AtEndOfStream
                    .SkipLine
                Loop
                Do Until .Line > ToLine Or .AtEndOfStream
                    ExtractLinesFromTextFile = ExtractLinesFromTextFile & (.ReadLine & vbNewLine)
                Loop
            End If
        End With
    Else
        MsgBox "Error to Read Line in TextFile", vbCritical,"Error to Read Line in TextFile"
    End If
End Function
'----------------------------------------------------------------------------------------------------
Sub WriteLog(strText,Log)
   Dim fs,ts
   Const ForWriting = 2
   Set fs = CreateObject("Scripting.FileSystemObject")
   Set ts = fs.OpenTextFile(Log,ForWriting, True)
   ts.WriteLine strText
   ts.Close
End Sub
'----------------------------------------------------------------------------------------------------
Sub ConvertToHTML(Filename)
   Dim fso, f, ts, Content, HTML, CSS, T, b, c, i, j, CurrentLine
   CSS = "<style>table{font-family:""Trebuchet MS"",Arial,Helvetica,sans-serif;border-collapse:collapse;width:100%}td,th{border:1px solid #ddd;padding:8px}tr:nth-child(even){background-color:#f2f2f2}tr:hover{background-color:#ddd}th{padding-top:12px;padding-bottom:12px;text-align:left;background-color:#4CAF50;color:#fff}</style>"
   HTML = "<html><head><meta charset=""utf-8"">" & CSS & "</head><body><table>"
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f = fso.OpenTextFile(LogFile, 1, True)
   Content = f.ReadAll
   f.Close
   T = Split(Content,vbCrLf)
   HTML = HTML & "<tr><td>Proxy address:port</td><td>Country</td><td>Anonymity(Noa/Anm/Hia)</td><td>SSL_support(S)</td><td>Google_passed(+)</td></tr>"
   b=ubound(T)
   For i=0 to b
      CurrentLine = Split(Replace(Replace(Trim(T(i))," ","!"),"-","!"),"!")
     c=ubound(CurrentLine)
     HTML = HTML & "<tr>"
      For j=0 to c
         if j = 3 then
            if CurrentLine(j) <> "S" then
               HTML = HTML & "<td style=""color: #f00;"">NO SSL</td>" & "<td>" & CurrentLine(j) & "</td>"
           Else
               HTML = HTML & "<td style=""color: #0f0;"">SSL</td>"
           End If
        Else
            if CurrentLine(j) <> "" then
               HTML = HTML & "<td>" & CurrentLine(j) & "</td>"
           Else
               if j = 4 then HTML = HTML & "<td>-</td>"
           End If
        End If
     Next
      HTML = HTML & "</tr>"
   Next
   HTML = Replace(HTML,"<td></td>","") & "</table></body></html>"
   Set ts = fso.OpenTextFile(Filename,2, -1)
   ts.Write HTML
   ts.Close
End Sub



Je suis pas très expérimenté en VBScript (le code est pas très propre) mais ça fonctionne Mr. Green

Capture d'écran du résultat :





______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message [R] Convertir un texte en tableau HTML ? 
Very Nice Flamm Okay
Tu n'es pas expert en vbscript hein Mr. Green Mort de rire




______________________________________________________
Mes Contributions en Téléchargement
Message [R] Convertir un texte en tableau HTML ? 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch