Batch Index du Forum
S’enregistrerRechercherFAQMembresGroupesConnexion
Répondre au sujet Page 1 sur 1
Comment télécharger un lien sécurisé de youtube ?
Auteur Message
Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
Salut !
Je reprends de nouveau ce projet en vbscript pour télécharger un lien sécurisé de Youtube !
Le problème c'est que je reçois toujours un message 403 interdit !
Alors si quelqu'un parmi vous nous donne une solution radiacle à ce problème ! Merci !

Voici le code vbscript que j'ai fait pour le moment !

Code:
Option Explicit
Dim Title,Converter,Youtube_URL,SourceCode,Videos,Video,ws,Download_Command,FileName,DEST,Temp
Title = "Youtube Downloader by Hackoo 2018"
Youtube_URL = InputBox("Veuillez saisir le lien de Youtube pour la conversion en lien direct et le télécharger" & vbcrlf & vbcrlf &_
"Please enter Youtube link for conversion to direct link and download it",Title,"https://www.youtube.com/watch?v=IJHPpTYtIqk")
If Youtube_URL = "" Then Wscript.Quit(1)
Converter="https://www.tubeoffline.to/downloadFrom.php?host=OnLine&video="&Youtube_URL
SourceCode = GetSourceCode(Converter)
Set ws = CreateObject("WScript.Shell")
Temp = ws.ExpandEnvironmentStrings("%Temp%")
Videos = Extracting_Videos(SourceCode)
FileName = "Balti.mp4"
DEST = Temp & "\YouTubeDownloader"
Call SmartCreateFolder(DEST)
For Each Video in Videos
   wscript.echo Video
   Download_Command = "Title "& Title & "& color 0A & echo; & echo; & echo    Please be patient Downloading "& DblQuote(FileName) &_
   "... & Powershell.exe -command ""(New-Object System.Net.WebClient).DownloadFile("& SimpleQuote(Video) & "," & SimpleQuote(DEST + "\" + FileName)&")"""
   Call Executer(Download_Command,1)
Next
'***********************************************************************
Function Executer(StrCmd,Console)
   Dim ws,MyCmd,Resultat
   Set ws = CreateObject("wscript.Shell")
'La valeur 0 pour cacher la console MS-DOS
   If Console = 0 Then
      MyCmd = "CMD /C " & StrCmd & ""
      Resultat = ws.run(MyCmd,Console,True)
      If Resultat = 0 Then
      Else
'MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
      End If
   End If
'La valeur 1 pour montrer la console MS-DOS
   If Console = 1 Then
      MyCmd = "CMD /K " & StrCmd & " "
      Resultat = ws.run(MyCmd,Console,True)
      If Resultat = 0 Then
      Else
'MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
      End If
   End If
   Executer = Resultat
End Function
'------------------------------------------------
Function SimpleQuote(Str)
   SimpleQuote = ChrW(39) & Str & ChrW(39)
End Function
'------------------------------------------------
Function DblQuote(Str)
   DblQuote = Chr(34) & Str & Chr(34)
End Function
'------------------------------------------------
Function Extracting_Videos(URL)
   Dim regEx, Match, Matches, Array_Videos,dico,K
   Set regEx = New RegExp
   regEx.Pattern = "<td>(.*?)</td><td>(.*?)</td><td><a href=.(.*?)"""
   regEx.IgnoreCase = True
   regEx.Global = False
   Set Matches = regEx.Execute(URL)
   Array_Videos = Array()
   Set dico = CreateObject("Scripting.Dictionary")
   For Each Match in Matches
      If Not dico.Exists(Match.Value) Then
         dico.Add Match.submatches(2),Match.submatches(2)
      End If
   Next
   For each K in dico.Keys()
      ReDim Preserve Array_Videos(UBound(Array_Videos) + 1)
      Array_Videos(UBound(Array_Videos)) = K
   Next
   Extracting_Videos = Array_Videos
End Function
'------------------------------------------------
Function GetFileName(URL)
   Dim ArrFile,FileName
   ArrFile = Split(URL,"/")
   FileName = ArrFile(UBound(ArrFile))
   GetFileName = FileName
End Function
'------------------------------------------------
Sub SmartCreateFolder(strFolder)
   With CreateObject("Scripting.FileSystemObject")
      If Not .FolderExists(strFolder) then
         SmartCreateFolder(.getparentfoldername(strFolder))
         .CreateFolder(strFolder)
      End If
   End With
End Sub
'------------------------------------------------
Function GetSourceCode(URL)
   Dim http
   Set http = CreateObject("Msxml2.XMLHTTP")
   http.open "GET",URL,False
   http.send
   GetSourceCode = http.responseText
End Function
'------------------------------------------------


Edit :

Je crois que j'ai trouvé une piste depuis un code écrit en php !

Ce que j'ai un peu compris depuis ce code c'est qu'il reconstruit l'url de youtube après avoir extrait le ID de la vidéo afin de récupérer des infos sur la vidéo depuis cette ligne :

$get_video_info = 'http://www.youtube.com/get_video_info?&video_id='. $id[1].'&asv=3&el=detailpage&hl=en_US';

Code PHP :
Code:
<?php
error_reporting(E_ERROR | E_PARSE);
header('Content-Type: text/html; charset=utf-8');
date_default_timezone_set("Asia/Kolkata");
function curl($url) {
    $ch = @curl_init();
    curl_setopt($ch, CURLOPT_URL, $url);
    $head[] = "Connection: keep-alive";
    $head[] = "Keep-Alive: 300";
    $head[] = "Accept-Charset: ISO-8859-1,utf-8;q=0.7,*;q=0.7";
    $head[] = "Accept-Language: en-us,en;q=0.5";
    curl_setopt($ch, CURLOPT_USERAGENT, 'Mozilla/5.0 (Windows NT 6.1; WOW64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/37.0.2062.124 Safari/537.36');
    curl_setopt($ch, CURLOPT_HTTPHEADER, $head);
    curl_setopt($ch, CURLOPT_RETURNTRANSFER, 1);
    curl_setopt($ch, CURLOPT_ENCODING , 'gzip, deflate');
    curl_setopt($ch, CURLOPT_SSL_VERIFYHOST, FALSE);
    curl_setopt($ch, CURLOPT_SSL_VERIFYPEER, FALSE);
    curl_setopt($ch, CURLOPT_TIMEOUT, 60);
    curl_setopt($ch, CURLOPT_CONNECTTIMEOUT, 60);
    curl_setopt($ch, CURLOPT_FOLLOWLOCATION, TRUE);
    curl_setopt($ch, CURLOPT_HTTPHEADER, array('Expect:'));
    $page = curl_exec($ch);
    curl_close($ch);
    return $page;
}
 
function get_size($url)
{
    $ch = curl_init();
    curl_setopt($ch, CURLOPT_URL,$url);
    curl_setopt($ch, CURLOPT_HEADER, true);
    curl_setopt($ch, CURLOPT_NOBODY, true);
    curl_setopt($ch, CURLOPT_RETURNTRANSFER, true);
    curl_setopt($ch, CURLOPT_TIMEOUT, 10);
    $r = curl_exec($ch);
    foreach(explode("\n", $r) as $header)
    {
        if(strpos($header, 'Content-Length:') === 0)
        {
            return trim(substr($header,16));
        }
    }
    return '';
}
 
ob_start();
function clean($string)
{
   $string = str_replace(' ', '-', $string);
   return preg_replace('/[^A-Za-z0-9\-]/', '', $string);
}
 
function formatBytes($bytes, $precision = 2)
{
    $units = array('B', 'kB', 'MB', 'GB', 'TB', 'PB', 'EB', 'ZB', 'YB');
    $bytes = max($bytes, 0);
    $pow = floor(($bytes ? log($bytes) : 0)/log(1024));
    $pow = min($pow, count($units) - 1);
    $bytes /= pow(1024, $pow);
    return round($bytes, $precision).''.$units[$pow];
}
 
$link = 'https://www.youtube.com/watch?v=_1z0EauKgaw';
$id = explode('?v=', $link);
$get_video_info = 'http://www.youtube.com/get_video_info?&video_id='. $id[1].'&asv=3&el=detailpage&hl=en_US';
$get_video_info = curl($get_video_info);
$thumbnail_url = $title = $url_encoded_fmt_stream_map = $type = $url = '';
parse_str($get_video_info);
 
$data = explode(',',$url_encoded_fmt_stream_map);
$expire = time();
foreach($data as $i => $format) {
    parse_str($format);
    $data_formats[$i]['itag'] = $itag;
    $data_formats[$i]['quality'] = $quality;
    $type = explode(';',$type);
    $data_formats[$i]['type'] = $type[0];
    $data_formats[$i]['url'] = urldecode($url).'&signature='.$sig;
    parse_str(urldecode($url));
    $data_formats[$i]['expires'] = date("G:i:s T", $expire);
    $data_formats[$i]['ipbits'] = $ipbits;
    $data_formats[$i]['ip'] = $ip;
    $i++;
}
 
echo "Title: ".$title."<br><img src='".$thumbnail_url."'><br>";
for($i=0; $i<count($data_formats); $i++)
{
    $type = $data_formats[$i]['type'];
    $quality = $data_formats[$i]['quality'];
    $fileSize = formatBytes(get_size($data_formats[$i]['url']));
    $download = $data_formats[$i]['url'].'&title='.clean($title);
    echo $type." | ".$quality." | ".$fileSize." | <a href='".$download."'>Download</a><br>";
}
?>





______________________________________________________
Mes Contributions en Téléchargement
Message Publicité 
PublicitéSupprimer les publicités ?


Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
https://codewithmark.com/learn-to-create-youtube-video-downloader

Supposons que j'ai eu ces infos depuis cette URL :

http://www.youtube.com/get_video_info?html5=1&video_id=QNJL6nfu__Q

Comment puis-je l'expoilter pour extraire l'url de téléchargement ???




______________________________________________________
Mes Contributions en Téléchargement
Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
Il n'y a pas une url de téléchargement, mais plusieurs possibles. Toutes aboutissent
sur des médias de différents formats, sans compter les dashes (dynamic adaptive
streaming over http). Les liens sont encodés dans les données adaptive_fmts et
url_encoded_fmt_stream_map, mais pour qu'ils soient utilisables, il faut parser
les chaines, extraire et décoder les urls. Cela dit, je ne pense pas que VBS peut
faire ça de manière native, dès lors 3 choix s'offrent à toi, faire la fonction de
décodage (ou en récupérer une sur le net), passer par un service en ligne qui
le fait, sinon changer d'outil.

exemple de début d'URL doublement encodée: https%253A%252F%252F
décodée (2 fois) ça donne : https://



Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
jay a écrit:
Il n'y a pas une url de téléchargement, mais plusieurs possibles. Toutes aboutissent
sur des médias de différents formats, sans compter les dashes (dynamic adaptive
streaming over http). Les liens sont encodés dans les données adaptive_fmts et
url_encoded_fmt_stream_map, mais pour qu'ils soient utilisables, il faut parser
les chaines, extraire et décoder les urls. Cela dit, je ne pense pas que VBS peut
faire ça de manière native, dès lors 3 choix s'offrent à toi, faire la fonction de
décodage (ou en récupérer une sur le net), passer par un service en ligne qui
le fait, sinon changer d'outil.

exemple de début d'URL doublement encodée: https%253A%252F%252F
décodée (2 fois) ça donne : https://


Merci Jay pour votre réponse !
D'après votre commentaire peut-être celle-ci est une piste ==> https://stackoverflow.com/questions/17880395/decoding-url-encoded-utf-8-str…
Qu'en pensez-vous ?

Code:
wscript.echo URLDecode(URLDecode("https%253A%252F%252F"))

Function URLDecode(str)
    set list = CreateObject("System.Collections.ArrayList")
    strLen = Len(str)
    for i = 1 to strLen
        sT = mid(str, i, 1)
        if sT = "%" then
            if i + 2 <= strLen then
                list.Add cbyte("&H" & mid(str, i + 1, 2))
                i = i + 2
            end if
        else
            list.Add asc(sT)
        end if
    next
    depth = 0
    for each by in list.ToArray()
        if by and &h80 then
            if (by and &h40) = 0 then
                if depth = 0 then Err.Raise 5
                val = val * 2 ^ 6 + (by and &h3f)
                depth = depth - 1
                if depth = 0 then
                    sR = sR & chrw(val)
                    val = 0
                end if
            elseif (by and &h20) = 0 then
                if depth > 0 then Err.Raise 5
                val = by and &h1f
                depth = 1
            elseif (by and &h10) = 0 then
                if depth > 0 then Err.Raise 5
                val = by and &h0f
                depth = 2
            else
                Err.Raise 5
            end if
        else
            if depth > 0 then Err.Raise 5
            sR = sR & chrw(by)
        end if
    next
    if depth > 0 then Err.Raise 5
    URLDecode = sR
End Function





______________________________________________________
Mes Contributions en Téléchargement
Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
Oui tu peux tester ce script sur le fichier téléchargé.



Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
Salut Wink
J'ai pu m'avancer un peu dans ce projet Okay
Il me reste juste un problème d'encodage des caractères du titre de la vidèo
Par exemple comme celle-ci avec tout les caractères en arabe : https://www.youtube.com/watch?v=RDHwxj6IkrY
J'obtiens des caractères comme ça : "كريم_مافيبالوش_جاب_زوز_توامى"
et par la suite je ne peux pas l'enregistrer Mad

Code:
Option Explicit
'ForceCScriptExecution
Dim Title,Converter,Youtube_URL,SourceCode,Videos,Video
Dim fso,ws,Download_Command,FileName,DEST,curDir,Temp,WaitingMsg
Title = "Youtube Downloader by Hackoo 2018"
Youtube_URL = InputBox("Veuillez saisir le lien de Youtube pour la conversion en lien direct et le télécharger" & vbcrlf & vbcrlf &_
"Please enter Youtube link for conversion to direct link and download it",Title,"https://www.youtube.com/watch?v=IJHPpTYtIqk")
If Youtube_URL = "" Then Wscript.Quit(1)
Converter="https://www.tubeoffline.to/downloadFrom.php?host=OnLine&video="&Youtube_URL
SourceCode = GetSourceCode(Converter)
Set ws = CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
curDir = fso.GetParentFolderName(wscript.ScriptFullName)
Temp = ws.ExpandEnvironmentStrings("%Temp%")
Videos = Extracting_Videos(SourceCode)
DEST = curDir & "\YouTubeDownloader"
Call SmartCreateFolder(DEST)

For Each Video in Videos
   Video = Replace(unescape(unescape(Video)),"&amp;","&")
   Video = Replace(Video,"&#x2B;","+")
   FileName = GetTitleVideo(video) & ".mp4"
   'FileName = Replace(FileName,"+","_")
   'FileName = Replace(FileName,"|","_")
   'FileName = Replace(FileName," ","_")
   'FileName = Replace(FileName,"'","_")
   'FileName = Replace(FileName,":","_")
   'FileName = Replace(FileName,",","_")
   'FileName = Replace(FileName,";","_")
   'FileName = Replace(FileName,"&","_")
   'FileName = Replace(FileName,chr(34),"_")
   FileName = unescape(unescape(FileName))
   WaitingMsg = DblQuote(FileName)
   Call CreateProgressBar(Title,WaitingMsg)
   Call LaunchProgressBar()
   'Download_Command = "Mode 100,3 & Title "& Title & "& color 0A & echo; & echo; & echo     Please be patient Downloading "& DblQuote(FileName) &_
   '"... & Powershell.exe -command ""(New-Object System.Net.WebClient).DownloadFile("& SimpleQuote(Video) & "," & SimpleQuote(DEST + "\" + FileName)&")"""
   'Call Executer(Download_Command,1)
   Call DownloadVideo(Video,DEST + "\" + FileName)
   Call CloseProgressBar()
   Explorer(DEST + "\" + FileName)
Next
'***********************************************************************
Function Executer(StrCmd,Console)
   Dim ws,MyCmd,Resultat
   Set ws = CreateObject("wscript.Shell")
'La valeur 0 pour cacher la console MS-DOS
   If Console = 0 Then
      MyCmd = "CMD /C " & StrCmd & ""
      Resultat = ws.run(MyCmd,Console,True)
      If Resultat = 0 Then
      Else
'MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
      End If
   End If
'La valeur 1 pour montrer la console MS-DOS
   If Console = 1 Then
      MyCmd = "CMD /C " & StrCmd & " "
      Resultat = ws.run(MyCmd,Console,True)
      If Resultat = 0 Then
      Else
'MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
      End If
   End If
   Executer = Resultat
End Function
'------------------------------------------------
Function SimpleQuote(Str)
   SimpleQuote = ChrW(39) & Str & ChrW(39)
End Function
'------------------------------------------------
Function DblQuote(Str)
   DblQuote = Chr(34) & Str & Chr(34)
End Function
'------------------------------------------------
Function Extracting_Videos(URL)
   Dim regEx, Match, Matches, Array_Videos,dico,K
   Set regEx = New RegExp
   regEx.Pattern = "<td>(.*?)</td><td>(.*?)</td><td><a href=.(.*?)"""
   regEx.IgnoreCase = True
   regEx.Global = False
   Set Matches = regEx.Execute(URL)
   Array_Videos = Array()
   Set dico = CreateObject("Scripting.Dictionary")
   For Each Match in Matches
      If Not dico.Exists(Match.Value) Then
         dico.Add Match.submatches(2),Match.submatches(2)
      End If
   Next
   For each K in dico.Keys()
      ReDim Preserve Array_Videos(UBound(Array_Videos) + 1)
      Array_Videos(UBound(Array_Videos)) = K
   Next
   Extracting_Videos = Array_Videos
End Function
'------------------------------------------------
Function GetFileName(URL)
   Dim ArrFile,FileName
   ArrFile = Split(URL,"/")
   FileName = ArrFile(UBound(ArrFile))
   GetFileName = FileName
End Function
'------------------------------------------------
Sub SmartCreateFolder(strFolder)
   With CreateObject("Scripting.FileSystemObject")
      If Not .FolderExists(strFolder) then
         SmartCreateFolder(.getparentfoldername(strFolder))
         .CreateFolder(strFolder)
      End If
   End With
End Sub
'------------------------------------------------
Function GetSourceCode(URL)
   Dim http
   Set http = CreateObject("Msxml2.XMLHTTP")
   http.open "GET",URL,False
   http.send
   GetSourceCode = http.responseText
End Function
'------------------------------------------------
Sub ForceCScriptExecution()
    Dim Title, Arg, Str, cmd
   Title = "Youtube Downloader by Hackoo 2018                                                   "
   cmd = "CMD /C Title " & Title &" & color 0A & Mode 150,3 & "
    If Not LCase( Right( WScript.FullName, 12 ) ) = "\cscript.exe" Then
        For Each Arg In WScript.Arguments
            If InStr( Arg, " " ) Then Arg = """" & Arg & """"
            Str = Str & " " & Arg
        Next
        CreateObject( "WScript.Shell" ).Run _
           cmd & "cscript //nologo """ & _
            WScript.ScriptFullName & _
            """ " & Str
        WScript.Quit
    End If
End Sub
'-------------------------------------------------
Function GetTitleVideo(URL)
   Dim oRE, oMatches, Match,VideoTitle
   set oRE = New RegExp
   oRE.IgnoreCase = True
   oRE.Global = False
   oRE.Pattern = "title=(.+)"
   set oMatches = oRE.Execute(URL)
   If not isEmpty(oMatches) then
      For Each Match in oMatches 
         VideoTitle = Match.SubMatches(0)
      Next
      GetTitleVideo = VideoTitle
   End if
End Function
'-------------------------------------------------
Function URLDecode(StringToDecode)
Dim TempAns,CurChr
CurChr = 1
Do Until CurChr - 1 = Len(StringToDecode)
  Select Case Mid(StringToDecode, CurChr, 1)
    Case "+"
      TempAns = TempAns & " "
    Case "%"
      TempAns = TempAns & Chr(Clng("&h" & _
         Mid(StringToDecode, CurChr + 1, 2)))
       CurChr = CurChr + 2
    Case Else
      TempAns = TempAns & Mid(StringToDecode, CurChr, 1)
  End Select

CurChr = CurChr + 1
Loop
URLDecode = TempAns
End Function
' URLDecode function in Perl for reference
' both VB and Perl versions must return same
'
' sub urldecode{
'  local($val)=@_;
'  $val=~s/\+/ /g;
'  $val=~s/%([0-9A-H]{2})/pack('C',hex($1))/ge;
'  return $val;
' }
'-------------------------------------------------
Sub Explorer(File)
   ws.run "Explorer /n,/select,"& File &"",1,True
End Sub
'-------------------------------------------------
Sub DownloadVideo(URL,FileName)
   Dim WinHttp, arrArray, oFSO, oADO, iCount, oTextFile
   Set WinHttp = CreateObject("WinHttp.WinHttpRequest.5.1")
   If WinHttp Is Nothing Then Set WinHttp = CreateObject("WinHttp.WinHttpRequest")
   WinHttp.Open "GET", URL, False
   WinHttp.Send
   arrArray = WinHttp.ResponseBody
   Set WinHttp = Nothing
   On Error Resume Next
   Set oADO = CreateObject("ADODB.Stream")
   If oADO Is Nothing Then
'Write via FSO
      Set oFSO = CreateObject("Scripting.FileSystemObject")
      Set oTextFile = oFSO.OpenTextFile(Filename, 2, True)
      For iCount = 0 to UBound(arrArray)
         oTextFile.Write Chr(255 And Ascb(Midb(arrArray,iCount + 1, 1)))
      Next
      oTextFile.Close
   Else
'Write via ADO
      oADO.Type = 1
      oADO.Open
      oADO.Write arrArray
      oADO.SaveToFile Filename, 2
      oADO.Close
   End If
   Set oADO = Nothing
   Set oTextFile = Nothing
   Set oFSO = Nothing
End Sub
'-------------------------------------------------
Sub CreateProgressBar(Title,WaitingMsg)
   Dim ws,fso,f,f2,ts,ts2,Ligne,i,fread,LireTout,NbLigneTotal,Temp,PathOutPutHTML,fhta,oExec
   Set ws = CreateObject("wscript.Shell")
   Set fso = CreateObject("Scripting.FileSystemObject")
   Temp = WS.ExpandEnvironmentStrings("%Temp%")
   PathOutPutHTML = Temp & "\Barre.hta"
   Set fhta = fso.OpenTextFile(PathOutPutHTML,2,True,-1)
   fhta.WriteLine "<HTML>"
   fhta.WriteLine "<meta charset=""UTF-8"" />"
   fhta.WriteLine "<HEAD>"
   fhta.WriteLine "<Title>  " & Title & "</Title>"
   fhta.WriteLine "<HTA:APPLICATION"
   fhta.WriteLine "ICON = ""magnify.exe"" "
   fhta.WriteLine "BORDER=""THIN"" "
   fhta.WriteLine "INNERBORDER=""NO"" "
   fhta.WriteLine "MAXIMIZEBUTTON=""NO"" "
   fhta.WriteLine "MINIMIZEBUTTON=""NO"" "
   fhta.WriteLine "SCROLL=""NO"" "
   fhta.WriteLine "SYSMENU=""NO"" "
   fhta.WriteLine "SELECTION=""NO"" "
   fhta.WriteLine "SINGLEINSTANCE=""YES"">"
   fhta.WriteLine "</HEAD>"
   fhta.WriteLine "<BODY text=""white""><CENTER>"
   fhta.WriteLine "<marquee DIRECTION=""LEFT"" SCROLLAMOUNT=""3"" BEHAVIOR=""ALTERNATE""><font face=""Comic sans MS"">" & WaitingMsg &" </font></marquee>"
   fhta.WriteLine "<img src=""data:image/gif;base64,R0lGODlhgAAPAPIAAP////INPvvI0/q1xPVLb/INPgAAAAAAACH/C05FVFNDQVBFMi4wAwEAAAAh/hpDcmVhdGVkIHdpdGggYWpheGxvYWQuaW5mbwAh+QQJCgAAACwAAAAAgAAPAAAD5wiyC/6sPRfFpPGqfKv2HTeBowiZGLORq1lJqfuW7Gud9YzLud3zQNVOGCO2jDZaEHZk+nRFJ7R5i1apSuQ0OZT+nleuNetdhrfob1kLXrvPariZLGfPuz66Hr8f8/9+gVh4YoOChYhpd4eKdgwDkJEDE5KRlJWTD5iZDpuXlZ+SoZaamKOQp5wAm56loK6isKSdprKotqqttK+7sb2zq6y8wcO6xL7HwMbLtb+3zrnNycKp1bjW0NjT0cXSzMLK3uLd5Mjf5uPo5eDa5+Hrz9vt6e/qosO/GvjJ+sj5F/sC+uMHcCCoBAAh+QQJCgAAACwAAAAAgAAPAAAD/wi0C/4ixgeloM5erDHonOWBFFlJoxiiTFtqWwa/Jhx/86nKdc7vuJ6mxaABbUaUTvljBo++pxO5nFQFxMY1aW12pV+q9yYGk6NlW5bAPQuh7yl6Hg/TLeu2fssf7/19Zn9meYFpd3J1bnCMiY0RhYCSgoaIdoqDhxoFnJ0FFAOhogOgo6GlpqijqqKspw+mrw6xpLCxrrWzsZ6duL62qcCrwq3EsgC0v7rBy8PNorycysi3xrnUzNjO2sXPx8nW07TRn+Hm3tfg6OLV6+fc37vR7Nnq8Ont9/Tb9v3yvPu66Xvnr16+gvwO3gKIIdszDw65Qdz2sCFFiRYFVmQFIAEBACH5BAkKAAAALAAAAACAAA8AAAP/CLQL/qw9J2qd1AoM9MYeF4KaWJKWmaJXxEyulI3zWa/39Xh6/vkT3q/DC/JiBFjMSCM2hUybUwrdFa3Pqw+pdEVxU3AViKVqwz30cKzmQpZl8ZlNn9uzeLPH7eCrv2l1eXKDgXd6Gn5+goiEjYaFa4eOFopwZJh/cZCPkpGAnhoFo6QFE6WkEwOrrAOqrauvsLKttKy2sQ+wuQ67rrq7uAOoo6fEwsjAs8q1zLfOvAC+yb3B0MPHD8Sm19TS1tXL4c3jz+XR093X28ao3unnv/Hv4N/i9uT45vqr7NrZ89QFHMhPXkF69+AV9OeA4UGBDwkqnFiPYsJg7jBktMXhD165jvk+YvCoD+Q+kRwTAAAh+QQJCgAAACwAAAAAgAAPAAAD/wi0C/6sPRfJdCLnC/S+nsCFo1dq5zeRoFlJ1Du91hOq3b3qNo/5OdZPGDT1QrSZDLIcGp2o47MYheJuImmVer0lmRVlWNslYndm4Jmctba5gm9sPI+gp2v3fZuH78t4Xk0Kg3J+bH9vfYtqjWlIhZF0h3qIlpWYlJpYhp2DjI+BoXyOoqYaBamqBROrqq2urA8DtLUDE7a1uLm3s7y7ucC2wrq+wca2sbIOyrCuxLTQvQ680wDV0tnIxdS/27TND+HMsdrdx+fD39bY6+bX3um14wD09O3y0e77+ezx8OgAqutnr5w4g/3e4RPIjaG+hPwc+stV8NlBixAzSlT4bxqhx46/MF5MxUGkPA4BT15IyRDlwG0uG55MAAAh+QQJCgAAACwAAAAAgAAPAAAD/wi0C/6sPRfJpPECwbnu3gUKH1h2ZziNKVlJWDW9FvSuI/nkusPjrF0OaBIGfTna7GaTNTPGIvK4GUZRV1WV+ssKlE/G0hmDTqVbdPeMZWvX6XacAy6LwzAF092b9+GAVnxEcjx1emSIZop3g16Eb4J+kH+ShnuMeYeHgVyWn56hakmYm6WYnaOihaCqrh0FsbIFE7Oytba0D7m6DgO/wAMTwcDDxMIPx8i+x8bEzsHQwLy4ttWz17fJzdvP3dHfxeG/0uTjywDK1Lu52bHuvenczN704Pbi+Ob66MrlA+scBAQwcKC/c/8SIlzI71/BduysRcTGUF49i/cw5tO4jytjv3keH0oUCJHkSI8KG1Y8qLIlypMm312ASZCiNA0X8eHMqPNCTo07iyUAACH5BAkKAAAALAAAAACAAA8AAAP/CLQL/qw9F8mk8ap8hffaB3ZiWJKfmaJgJWHV5FqQK9uPuDr6yPeTniAIzBV/utktVmPCOE8GUTc9Ia0AYXWXPXaTuOhr4yRDzVIjVY3VsrnuK7ynbJ7rYlp+6/u2vXF+c2tyHnhoY4eKYYJ9gY+AkYSNAotllneMkJObf5ySIphpe3ajiHqUfENvjqCDniIFsrMFE7Sztre1D7q7Dr0TA8LDA8HEwsbHycTLw83ID8fCwLy6ubfXtNm40dLPxd3K4czjzuXQDtID1L/W1djv2vHc6d7n4PXi+eT75v3oANSxAzCwoLt28P7hC2hP4beH974ZTEjwYEWKA9VBdBixLSNHhRPlIRR5kWTGhgz1peS30l9LgBojUhzpa56GmSVr9tOgcueFni15styZAAAh+QQJCgAAACwAAAAAgAAPAAAD/wi0C/6sPRfJpPGqfKsWIPiFwhia4kWWKrl5UGXFMFa/nJ0Da+r0rF9vAiQOH0DZTMeYKJ0y6O2JPApXRmxVe3VtSVSmRLzENWm7MM+65ra93dNXHgep71H0mSzdFec+b3SCgX91AnhTeXx6Y2aOhoRBkllwlICIi49liWmaapGhbKJuSZ+niqmeN6SWrYOvIAWztAUTtbS3uLYPu7wOvrq4EwPFxgPEx8XJyszHzsbQxcG9u8K117nVw9vYD8rL3+DSyOLN5s/oxtTA1t3a7dzx3vPwAODlDvjk/Orh+uDYARBI0F29WdkQ+st3b9zCfgDPRTxWUN5AgxctVqTXUDNix3QToz0cGXIaxo32UCo8+OujyJIM95F0+Y8mMov1NODMuPKdTo4hNXgMemGoS6HPEgAAIfkECQoAAAAsAAAAAIAADwAAA/8ItAv+rD0XyaTxqnyr9pcgitpIhmaZouMGYq/LwbPMTJVE34/Z9j7BJCgE+obBnAWSwzWZMaUz+nQQkUfjyhrEmqTQGnins5XH5iU3u94Crtpfe4SuV9NT8R0Nn5/8RYBedHuFVId6iDyCcX9vXY2Bjz52imeGiZmLk259nHKfjkSVmpeWanhhm56skIyABbGyBROzsrW2tA+5ug68uLbAsxMDxcYDxMfFycrMx87Gv7u5wrfTwdfD2da+1A/Ky9/g0OEO4MjiytLd2Oza7twA6/Le8LHk6Obj6c/8xvjzAtaj147gO4Px5p3Dx9BfOQDnBBaUeJBiwoELHeaDuE8uXzONFu9tE2mvF0KSJ00q7Mjxo8d+L/9pRKihILyaB29esEnzgkt/Gn7GDPosAQAh+QQJCgAAACwAAAAAgAAPAAAD/wi0C/6sPRfJpPGqfKv2HTcJJKmV5oUKJ7qBGPyKMzNVUkzjFoSPK9YjKHQQgSve7eeTKZs7ps4GpRqDSNcQu01Kazlwbxp+ksfipezY1V5X2ZI5XS1/5/j7l/12A/h/QXlOeoSGUYdWgXBtJXEpfXKFiJSKg5V2a1yRkIt+RJeWk6KJmZhogKmbniUFrq8FE7CvsrOxD7a3Drm1s72wv7QPA8TFAxPGxcjJx8PMvLi2wa7TugDQu9LRvtvAzsnL4N/G4cbY19rZ3Ore7MLu1N3v6OsAzM0O9+XK48Xn/+notRM4D2C9c/r6Edu3UOEAgwMhFgwoMR48awnzMWOIzyfeM4ogD4aMOHJivYwexWlUmZJcPXcaXhKMORDmBZkyWa5suE8DuAQAIfkECQoAAAAsAAAAAIAADwAAA/8ItAv+rD0XyaTxqnyr9h03gZNgmtqJXqqwka8YM2NlQXYN2ze254/WyiF0BYU8nSyJ+zmXQB8UViwJrS2mlNacerlbSbg3E5fJ1WMLq9KeleB3N+6uR+XEq1rFPtmfdHd/X2aDcWl5a3t+go2AhY6EZIZmiACWRZSTkYGPm55wlXqJfIsmBaipBROqqaytqw+wsQ6zr623qrmusrATA8DBA7/CwMTFtr24yrrMvLW+zqi709K0AMkOxcYP28Pd29nY0dDL5c3nz+Pm6+jt6uLex8LzweL35O/V6fv61/js4m2rx01buHwA3SWEh7BhwHzywBUjOGBhP4v/HCrUyJAbXUSDEyXSY5dOA8l3Jt2VvHCypUoAIetpmJgAACH5BAkKAAAALAAAAACAAA8AAAP/CLQL/qw9F8mk8ap8q/YdN4Gj+AgoqqVqJWHkFrsW5Jbzbee8yaaTH4qGMxF3Rh0s2WMUnUioQygICo9LqYzJ1WK3XiX4Na5Nhdbfdy1mN8nuLlxMTbPi4be5/Jzr+3tfdSdXbYZ/UX5ygYeLdkCEao15jomMiFmKlFqDZz8FoKEFE6KhpKWjD6ipDqunpa+isaaqqLOgEwO6uwO5vLqutbDCssS0rbbGuMqsAMHIw9DFDr+6vr/PzsnSx9rR3tPg3dnk2+LL1NXXvOXf7eHv4+bx6OfN1b0P+PTN/Lf98wK6ExgO37pd/pj9W6iwIbd6CdP9OmjtGzcNFsVhDHfxDELGjxw1Xpg4kheABAAh+QQJCgAAACwAAAAAgAAPAAAD/wi0C/6sPRfJpPGqfKv2HTeBowiZjqCqG9malYS5sXXScYnvcP6swJqux2MMjTeiEjlbyl5MAHAlTEarzasv+8RCu9uvjTuWTgXedFhdBLfLbGf5jF7b30e3PA+/739ncVp4VnqDf2R8ioBTgoaPfYSJhZGIYhN0BZqbBROcm56fnQ+iow6loZ+pnKugpKKtmrGmAAO2twOor6q7rL2up7C/ssO0usG8yL7KwLW4tscA0dPCzMTWxtXS2tTJ297P0Nzj3t3L3+fmzerX6M3hueTp8uv07ezZ5fa08Piz/8UAYhPo7t6+CfDcafDGbOG5hhcYKoz4cGIrh80cPAOQAAAh+QQJCgAAACwAAAAAgAAPAAAD5wi0C/6sPRfJpPGqfKv2HTeBowiZGLORq1lJqfuW7Gud9YzLud3zQNVOGCO2jDZaEHZk+nRFJ7R5i1apSuQ0OZT+nleuNetdhrfob1kLXrvPariZLGfPuz66Hr8f8/9+gVh4YoOChYhpd4eKdgwFkJEFE5KRlJWTD5iZDpuXlZ+SoZaamKOQp5wAm56loK6isKSdprKotqqttK+7sb2zq6y8wcO6xL7HwMbLtb+3zrnNycKp1bjW0NjT0cXSzMLK3uLd5Mjf5uPo5eDa5+Hrz9vt6e/qosO/GvjJ+sj5F/sC+uMHcCCoBAA7AAAAAAAAAAAA"" />"
   fhta.WriteLine "</CENTER></BODY></HTML>"
   fhta.WriteLine "<SCRIPT LANGUAGE=""VBScript""> "
   fhta.WriteLine "Set ws = CreateObject(""wscript.Shell"")"
   fhta.WriteLine "Temp = WS.ExpandEnvironmentStrings(""%Temp%"")"
   fhta.WriteLine "Sub window_onload()"
   fhta.WriteLine "    CenterWindow 500,100"
   fhta.WriteLine "    Self.document.bgColor = ""DarkOrange"" "
   fhta.WriteLine " End Sub"
   fhta.WriteLine " Sub CenterWindow(x,y)"
   fhta.WriteLine "    Dim iLeft,itop"
   fhta.WriteLine "    window.resizeTo x,y"
   fhta.WriteLine "    iLeft = window.screen.availWidth/2 - x/2"
   fhta.WriteLine "    itop = window.screen.availHeight/2 - y/2"
   fhta.WriteLine "    window.moveTo ileft,itop"
   fhta.WriteLine " End Sub"
   fhta.WriteLine "'***********************************************************"
   fhta.WriteLine "Function DblQuote(Str)"
   fhta.WriteLine "   DblQuote = Chr(34) & Str & Chr(34)"
   fhta.WriteLine "End Function"
   fhta.WriteLine "'***********************************************************"
    fhta.WriteLine "</script>"
    fhta.close
End Sub
'**********************************************************************************************
Sub LaunchProgressBar()
   Dim Launch
   Set ws = CreateObject("wscript.shell")
    Launch = Ws.run("mshta.exe " & Temp & "\Barre.hta",1,False)
End Sub
'**********************************************************************************************
Sub CloseProgressBar()
    Dim Close_HTA
   Set ws = CreateObject("wscript.shell")
   Close_HTA = Ws.Run("Taskkill /im ""mshta.exe"" /f",0,True)
End Sub
'**********************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'**********************************************************************************************





______________________________________________________
Mes Contributions en Téléchargement
Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
Malheureusement, ton script n'a rien à voir avec ton message du début,
tu passes par "tubeoffline" au lieu de "youtube/get_video_info". En ce
qui concerne ton problème d'enregistrement du titre, ça peut être dû à
la chaine de caractère qui est en utf8 là où Windows s'attend à avoir un
code page 1252 ou quelque chose comme ça. Peut-être que tu peux faire
la conversion avec adodb.stream.

15 jours pour faire un retour c'est probablement un peu beaucoup Evil or Very Mad



Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
Hackoo a écrit:
Salut !
Je reprends de nouveau ce projet en vbscript pour télécharger un lien sécurisé de Youtube !
Le problème c'est que je reçois toujours un message 403 interdit !
Alors si quelqu'un parmi vous nous donne une solution radiacle à ce problème ! Merci !

Voici le code vbscript que j'ai fait pour le moment !

{{{YouTube_Downloader.vbs}}}

Edit :

Je crois que j'ai trouvé une piste depuis un code écrit en php !

Ce que j'ai un peu compris depuis ce code c'est qu'il reconstruit l'url de youtube après avoir extrait le ID de la vidéo afin de récupérer des infos sur la vidéo depuis cette ligne :

$get_video_info = 'http://www.youtube.com/get_video_info?&video_id='. $id[1].'&asv=3&el=detailpage&hl=en_US';

Code PHP :
{{{YouTube_Grabber.php}}}


En fait, il suffit simplement de manipuler les données reçu de http://www.youtube.com/get_video_info?&video_id=
Donc à partir de ça j'ai fait un downloader de video youtube en vbscript (et un peu de mshta pour la déco) Laughing : https://pastebin.com/NiChW1Bb




______________________________________________________
la vie est trop courte pour retirer le périphérique USB en toute sécurité...
Si la statue de la liberté lève le bras depuis 125 ans, c'est parce qu'elle cherche du réseau sur son Blackberry Torches...
Grâce à mon nouveau correcteur automatiste sur mon téléphage, je ne fais plus aucune faute d'orthodontie.
Quelqu'un a t il déjà demandé au drapeau japonais ce qu'il enregistre depuis tout ce temps ?
Visiter le site web du posteur
Répondre en citant
Message Comment télécharger un lien sécurisé de youtube ? 
Merci Flamm pour votre code;
Je vais jeter un coup d'oeil et expoilter ce que tu me proposes comme solution Okay




______________________________________________________
Mes Contributions en Téléchargement
Message Comment télécharger un lien sécurisé de youtube ? 


Montrer les messages depuis:
Répondre au sujet Page 1 sur 1
  



Index | créer un forum | Forum gratuit d’entraide | Annuaire des forums gratuits | Signaler une violation | Conditions générales d'utilisation
Copyright 2008 - 2016 // Batch